Source: autoconf-archive
Version: 20190106-2.1
Tags: patch upstream
User: debian-cr...@lists.debian.org
Usertags: ftcbfs
Control: affects -1 + src:telegram-cli
telegram-cli fails to cross build from source, because it uses
AX_LUA_HEADERS, which happens to use AC_RUN_IFELSE to compute the lua
version. As it turns out, the version is also available as an integer,
which allows using the cross-friendly AC_COMPUTE_INT. The attached patch
updates AX_LUA_HEADERS to use AC_COMPUTE_INT. Please consider applying
it to make telegram-cli cross buildable.
Helmut
--- autoconf-archive-20190106.orig/m4/ax_lua.m4
+++ autoconf-archive-20190106/m4/ax_lua.m4
@@ -524,22 +524,17 @@ AC_DEFUN([AX_LUA_HEADERS],
[ax_cv_lua_header_version],
[ _ax_lua_saved_cppflags=$CPPFLAGS
CPPFLAGS="$CPPFLAGS $LUA_INCLUDE"
- AC_RUN_IFELSE(
- [ AC_LANG_SOURCE([[
+ AC_COMPUTE_INT(ax_cv_lua_header_version_major,[LUA_VERSION_NUM/100],[AC_INCLUDES_DEFAULT
#include <lua.h>
-#include <stdlib.h>
-#include <stdio.h>
-int main(int argc, char ** argv)
-{
- if(argc > 1) printf("%s", LUA_VERSION);
- exit(EXIT_SUCCESS);
-}
-]])
- ],
- [ ax_cv_lua_header_version=`./conftest$EXEEXT p | \
- $SED -n "s|^Lua \(@<:@0-9@:>@\{1,\}\.@<:@0-9@:>@\{1,\}\).\{0,\}|\1|p"`
- ],
- [ax_cv_lua_header_version='unknown'])
+],[ax_cv_lua_header_version_major=unknown])
+ AC_COMPUTE_INT(ax_cv_lua_header_version_minor,[LUA_VERSION_NUM%100],[AC_INCLUDES_DEFAULT
+#include <lua.h>
+],[ax_cv_lua_header_version_minor=unknown])
+ AS_IF([test "x$ax_cv_lua_header_version_major" = xunknown || test "x$ax_cv_lua_header_version_minor" = xunknown],[
+ ax_cv_lua_header_version=unknown
+ ],[
+ ax_cv_lua_header_version="$ax_cv_lua_header_version_major.$ax_cv_lua_header_version_minor"
+ ])
CPPFLAGS=$_ax_lua_saved_cppflags
])
