[gentoo-commits] repo/gentoo:master commit in: dev-python/pynvim/

[Michał Górny]

commit:     c5a368cfad3c7183b48abd360454b94cb49ed340
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 30 07:08:08 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Dec 30 07:16:44 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c5a368cf

dev-python/pynvim: Bump to 0.5.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pynvim/Manifest            |  1 +
 dev-python/pynvim/pynvim-0.5.2.ebuild | 52 +++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/dev-python/pynvim/Manifest b/dev-python/pynvim/Manifest
index 8faa34947388..d92ff7d0f041 100644
--- a/dev-python/pynvim/Manifest
+++ b/dev-python/pynvim/Manifest
@@ -1 +1,2 @@
 DIST pynvim-0.5.0.gh.tar.gz 59043 BLAKE2B 
4c9ce46e90dbb6cf278b48a904bef6dbd821d696c578a29d84af5ee64b223c602727dd09bdecbc90f7b6a634cbcd11b615d7ae48782e5cf71ae59faf8f8b1ff2
 SHA512 
91ffe3f42cc23ba372223b8c9f6930b0cff9d30b6764052a77a5c34e39a3312a1834b9a753152e96d04d5b4b61ce647bd7470095fac3122ae6b1346dcdf07f2f
+DIST pynvim-0.5.2.gh.tar.gz 61269 BLAKE2B 
252c9e38935cfb8558ad0536090942b5dbd582f5164c7172fb85e0fa76ba50f18c6be42831905599e28c6a1c074af7c71d7b35b6a37560a28f7bb8a11fcc7b5b
 SHA512 
3bc07e6e1aec265d9584cb03946a0d72fbd43be498bfcefc35d6b60f23316d1dd0ea812f24d96a0e156bd54918944b3cce6303f9a66b23e61c9a000233aa10eb

diff --git a/dev-python/pynvim/pynvim-0.5.2.ebuild 
b/dev-python/pynvim/pynvim-0.5.2.ebuild
new file mode 100644
index 000000000000..18ec98ab49f8
--- /dev/null
+++ b/dev-python/pynvim/pynvim-0.5.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Neovim"
+HOMEPAGE="
+       https://github.com/neovim/pynvim/
+       https://pypi.org/project/pynvim/
+"
+SRC_URI="
+       https://github.com/neovim/pynvim/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+       dev-python/msgpack[${PYTHON_USEDEP}]
+       $(python_gen_cond_dep '
+               >=dev-python/greenlet-3.0[${PYTHON_USEDEP}]
+       ' 'python*')
+       $(python_gen_cond_dep '
+               >=dev-python/typing-extensions-4.5[${PYTHON_USEDEP}]
+       ' 3.11 3.12)
+"
+BDEPEND="
+       test? (
+               app-editors/neovim
+               dev-python/pytest-timeout[${PYTHON_USEDEP}]
+       )
+"
+
+: ${EPYTEST_TIMEOUT:=5}
+distutils_enable_tests pytest
+
+python_test() {
+       local EPYTEST_DESELECT=(
+               # hangs
+               test/test_events.py::test_broadcast
+       )
+
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       epytest
+}