commit: cc5ce3692c00011c1729696e876c42c426b426e1
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 25 05:11:00 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Mar 25 05:33:45 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc5ce369
dev-python/kombu: Bump to 5.5.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/kombu/Manifest | 1 +
dev-python/kombu/kombu-5.5.1.ebuild | 96 +++++++++++++++++++++++++++++++++++++
2 files changed, 97 insertions(+)
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 1c2a210f5c2f..e2aab48ae560 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
DIST kombu-5.5.0.tar.gz 460768 BLAKE2B
9dcf5eb966b9ec98acd659adece254503f21fd6e6976ae882e0d78a9701cbb5bec7a84938d8d4cc438c326d50d0bf8165a48f61f061afa913e92edf443013883
SHA512
25d5c3b168c31a1de97188be0f55c6df858533e36040d64363de2edeb8562c019a249e8b608b192ac2482ce7d73fd48838e5890f78c488c30b2d9626c8352b7e
+DIST kombu-5.5.1.tar.gz 461398 BLAKE2B
c9b26be04e9c2f20ba099d8eb28d6b62fddfbc177510cb92f2b75a3d3e5a4f8453aa3322e0de5e487fa445b7b3a1a24ddcc27c1d83fcf893a303e35f5048d444
SHA512
ddc417107274c2e280b59f994b49f34bb74515dea3e1900b4eeb1426ec65c93b13db859a727b3dc0781d6fe7e84c65397c9ddb41c7647314f0fdf189549e93e3
diff --git a/dev-python/kombu/kombu-5.5.1.ebuild
b/dev-python/kombu/kombu-5.5.1.ebuild
new file mode 100644
index 000000000000..af319167e953
--- /dev/null
+++ b/dev-python/kombu/kombu-5.5.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+ https://github.com/celery/kombu/
+ https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+ <dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+ dev-python/tzdata[${PYTHON_USEDEP}]
+ dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ >=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+ dev-python/pycurl[${PYTHON_USEDEP}]
+ >=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+ dev-python/pytest-freezer[${PYTHON_USEDEP}]
+ dev-python/zstandard[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+ >=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+ dev-python/sphinx-celery
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unpin deps (notably tzdata, sigh)
+ > requirements/default.txt || die
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+
t/unit/transport/test_redis.py::test_Channel::test_global_keyprefix_transaction
+ # bad filename assumption?
+
t/unit/asynchronous/aws/test_connection.py::test_AsyncHTTPSConnection::test_request_with_cert_path_https
+ )
+ local EPYTEST_IGNORE=(
+ # obsolete Pyro4
+ t/unit/transport/test_pyro.py
+ # unpackaged azure
+ t/unit/transport/test_azurestoragequeues.py
+ # unpackage google-cloud
+ t/unit/transport/test_gcpubsub.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+ optfeature "Etcd backend" dev-python/python-etcd
+ optfeature "MongoDB backend" dev-python/pymongo
+ optfeature "Redis backend" dev-python/redis
+ optfeature "sqlalchemy backend" dev-python/sqlalchemy
+ optfeature "yaml backend" dev-python/pyyaml
+ optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+ optfeature "brotli compression" "app-arch/brotli[python]"
+ optfeature "zstd compression" dev-python/zstandard
+}
