commit: a2e01cc944802d49975c3db150f6a754ff5f294d
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 8 04:34:27 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Apr 8 04:45:05 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a2e01cc9
dev-python/hatch: Bump to 1.14.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hatch/Manifest | 1 +
dev-python/hatch/hatch-1.14.1.ebuild | 77 ++++++++++++++++++++++++++++++++++++
2 files changed, 78 insertions(+)
diff --git a/dev-python/hatch/Manifest b/dev-python/hatch/Manifest
index dcbe2ac39977..0cc3c4959bf2 100644
--- a/dev-python/hatch/Manifest
+++ b/dev-python/hatch/Manifest
@@ -1 +1,2 @@
DIST hatch-1.14.0.tar.gz 5188143 BLAKE2B
e018bb96f08f8ba390b4681f376d69c8f50d16254dcababf5ca308f46aa3b2f654a0af88b883130d2f4255c440c9a3038e2640a6ffdb6e3449ca73b898eef032
SHA512
bb0b6e03cb2174f9c761b4b322c8da00949e0afab779d8506ebc24773f809e04f2c7ec7b54b450de860fdc8ebe5063011d2d085ea133f3c7ad3c40bcfe28f335
+DIST hatch-1.14.1.tar.gz 5188180 BLAKE2B
0ddd06ad2848b892eaab6259885425f43a0a57383c1924eba2174afe768c702aca05ae018ecfd04bd1564eb043f1e6a314f5562e299d1a4ea6edd00b9622abe4
SHA512
db2790ccff3a9bd3d901f19754068a10fbe4d4ec5308396d87c043725ba340418e21af5616eaa0a26e69208d49796db08f837c23442ae63998bbf916a212cb01
diff --git a/dev-python/hatch/hatch-1.14.1.ebuild
b/dev-python/hatch/hatch-1.14.1.ebuild
new file mode 100644
index 000000000000..f1b208a03bb2
--- /dev/null
+++ b/dev-python/hatch/hatch-1.14.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 pypy3_11 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Modern, extensible Python project management"
+HOMEPAGE="
+ https://github.com/pypa/hatch/
+ https://pypi.org/project/hatch/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=dev-python/click-8.0.6[${PYTHON_USEDEP}]
+ >=dev-python/hatchling-1.24.2[${PYTHON_USEDEP}]
+ >=dev-python/httpx-0.22.0[${PYTHON_USEDEP}]
+ >=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
+ >=dev-python/keyring-23.5.0[${PYTHON_USEDEP}]
+ >=dev-python/packaging-24.2[${PYTHON_USEDEP}]
+ <dev-python/pexpect-5[${PYTHON_USEDEP}]
+ >=dev-python/pexpect-4.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.5.0[${PYTHON_USEDEP}]
+ dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+ >=dev-python/rich-11.2.0[${PYTHON_USEDEP}]
+ >=dev-python/shellingham-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/tomli-w-1.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.11.1[${PYTHON_USEDEP}]
+ <dev-python/userpath-2[${PYTHON_USEDEP}]
+ >=dev-python/userpath-1.7[${PYTHON_USEDEP}]
+ >=dev-python/uv-0.5.23
+ >=dev-python/virtualenv-20.26.6[${PYTHON_USEDEP}]
+ <dev-python/zstandard-1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/hatch-vcs-0.3.0[${PYTHON_USEDEP}]
+ test? (
+ dev-python/editables[${PYTHON_USEDEP}]
+ dev-python/filelock[${PYTHON_USEDEP}]
+ dev-python/flit-core[${PYTHON_USEDEP}]
+ dev-python/pyfakefs[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # we don't install .dist-info for uv
+ sed -i -e '/uv/d' pyproject.toml || die
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/cli/env/test_create.py::test_uv_env
+ )
+ local EPYTEST_IGNORE=(
+ # we're running these in dev-python/hatchling
+ tests/backend
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p pytest_fakefs -p pytest_mock \
+ -m "not requires_internet and not requires_docker"
+}
