commit: 9732d9ca750201d569a0d48fda43af8342bcacf1
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 15 04:57:33 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Apr 15 06:13:12 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9732d9ca
dev-python/pycairo: Bump to 1.28.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pycairo/Manifest | 1 +
dev-python/pycairo/pycairo-1.28.0.ebuild | 75 ++++++++++++++++++++++++++++++++
2 files changed, 76 insertions(+)
diff --git a/dev-python/pycairo/Manifest b/dev-python/pycairo/Manifest
index 806fc91a4167..544ac345dac1 100644
--- a/dev-python/pycairo/Manifest
+++ b/dev-python/pycairo/Manifest
@@ -1 +1,2 @@
DIST pycairo-1.27.0.tar.gz 661450 BLAKE2B
cc1ef54057d02f3e25fed010c995e4fe400ccdf3a5d2f241c029ded167c5db2560a4d9c8cb09b2f0519e674b5962f2244f0570401f45743fe1ec61d5a8982227
SHA512
1b077917b1d99262da1c1d2ff85ae841dd0ff715925a5a20032162aa876576d966fc6b30c154343cc45f104cce243887de9b5f14af1e15775cb71b6c11e553a6
+DIST pycairo-1.28.0.tar.gz 662477 BLAKE2B
26ab0ab926bc209c33eeff2f7578d31ffce138111e923f6bc8e31a5e318f7ead9d0350ee5717e3774c65eb8ac9f3324ff0446c316469796dc866c3530ef2d0dc
SHA512
d3fcb6641ad6dcf9b804dbc2a372f653619512e139fb7a196bb1219b00f60e79e5d60fbbddc2e6a0afb959f9fcb37f1f3c460ad6331274581cb241434865b5a5
diff --git a/dev-python/pycairo/pycairo-1.28.0.ebuild
b/dev-python/pycairo/pycairo-1.28.0.ebuild
new file mode 100644
index 000000000000..1f04f82bf43b
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.28.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{10..13} pypy3 pypy3_11 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit meson distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="
+ https://www.cairographics.org/pycairo/
+ https://github.com/pygobject/pycairo/
+ https://pypi.org/project/pycairo/
+"
+SRC_URI="
+ https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz
+"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="X examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=x11-libs/cairo-1.15.10[svg(+),X=]
+"
+DEPEND="
+ ${RDEPEND}
+ x11-base/xorg-proto
+"
+BDEPEND="
+ virtual/pkgconfig
+ test? (
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_sphinx docs \
+ dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_compile() {
+ local emesonargs=(
+ # TODO: move that to the eclass?
+ -Dpython.bytecompile=2
+ -Dtests="$(usex test true false)"
+ )
+
+ meson_src_configure
+ meson_src_compile
+}
+
+python_test() {
+ cd "${BUILD_DIR}" || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
+
+python_install() {
+ meson_src_install
+}
+
+python_install_all() {
+ if use examples; then
+ dodoc -r examples
+ fi
+
+ distutils-r1_python_install_all
+}
