commit: 4d7b3c4e89fc1d84293437e221e4a7b16682c254
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 15 05:25:54 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Apr 15 06:13:22 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d7b3c4e
dev-python/sympy: Bump to 1.14.0_rc1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sympy/Manifest | 1 +
dev-python/sympy/sympy-1.14.0_rc1.ebuild | 83 ++++++++++++++++++++++++++++++++
2 files changed, 84 insertions(+)
diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index 8e71cfe20b0d..6f1d476354a1 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1 +1,2 @@
DIST sympy-1.13.3.gh.tar.gz 7919933 BLAKE2B
94c601e79caf87eb0f08e15ca4cb79e16bcd97d347e1fd948b6ea98b044133ea99f52032f09e290668e4485393425254ff4062ccfd3a3ac0b8afba080da6ba19
SHA512
2ae7a400d4a2d9c826cfaa165e3e1f5d9ba210c25647984d997775d4ec3d7c8f3ad3c5468d9adf141a1dceec864ca988b4f3a01fd934b923c4486ddd458670a3
+DIST sympy-1.14.0rc1.gh.tar.gz 7910059 BLAKE2B
aee2c8c737497204be6ebceacfb516c49a027bb715975c636b76b959e4fab13a5bd2d59e516c56f9722633e3234af573a988f17bfab484bbd26f0d30ee5a8c69
SHA512
567c713eeb8cddbf8238afd46a5aba1931427e7a9834a779007c91018ae2d108ebc3f8cfba185a757109c46c2817a29d0dc04d7d419b1b619bcba52b899e3e3e
diff --git a/dev-python/sympy/sympy-1.14.0_rc1.ebuild
b/dev-python/sympy/sympy-1.14.0_rc1.ebuild
new file mode 100644
index 000000000000..ec67abc046c1
--- /dev/null
+++ b/dev-python/sympy/sympy-1.14.0_rc1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 pypy3_11 python3_{10..13} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="
+ https://www.sympy.org/
+ https://github.com/sympy/sympy/
+ https://pypi.org/project/sympy/
+"
+# pypi sdist misses some files, notably top-level conftest.py, as of 1.12.1_rc1
+SRC_URI="
+ https://github.com/sympy/sympy/archive/${PV/_/}.tar.gz
+ -> ${P/_/}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux
~ppc-macos ~x64-macos"
+IUSE="imaging ipython latex mathml pdf png pyglet symengine texmacs"
+
+RDEPEND="
+ >=dev-python/mpmath-1.1.0[${PYTHON_USEDEP}]
+ imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+ ipython? (
+ dev-python/ipython[${PYTHON_USEDEP}]
+ )
+ latex? (
+ virtual/latex-base
+ dev-texlive/texlive-fontsextra
+ png? ( app-text/dvipng )
+ pdf? ( app-text/ghostscript-gpl )
+ )
+ mathml? ( dev-python/lxml[${PYTHON_USEDEP}] )
+ pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+ symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+ texmacs? ( app-office/texmacs )
+"
+BDEPEND="
+ test? (
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_test() {
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # require old version of antlr4, also deprecated
+ # https://github.com/sympy/sympy/issues/27026
+ sympy/parsing/tests/test_autolev.py
+ sympy/parsing/tests/test_latex.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ nonfatal epytest --veryquickcheck ||
+ die -n "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ local DOCS=( AUTHORS README.md )
+
+ distutils-r1_python_install_all
+
+ if use texmacs; then
+ exeinto /usr/libexec/TeXmacs/bin/
+ doexe data/TeXmacs/bin/tm_sympy
+ insinto /usr/share/TeXmacs/plugins/sympy/
+ doins -r data/TeXmacs/progs
+ fi
+}
