[gentoo-commits] repo/gentoo:master commit in: dev-python/textx/

[Michał Górny]

commit:     4670af30a955f28e225a343d6c6583eaa7266edb
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri May  9 01:33:10 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri May  9 01:49:12 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4670af30

dev-python/textx: Bump to 4.2.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/textx/Manifest           |  1 +
 dev-python/textx/textx-4.2.0.ebuild | 59 +++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/textx/Manifest b/dev-python/textx/Manifest
index 2f0ffaec2584..65af8be048ed 100644
--- a/dev-python/textx/Manifest
+++ b/dev-python/textx/Manifest
@@ -1 +1,2 @@
 DIST textX-4.1.0.gh.tar.gz 2136599 BLAKE2B 
d6c7d4d741b4e526d0a71743387ee8455cc861bc4b356c605b6d174adb870bd178fd557a804f170f3d411b3ae70845771f7ffa7bbe9c4d1053c3d87e062deddb
 SHA512 
313fea5b6d9e94e280a0614d4130872229536fe39d5af6e440a08babe6c4e5a5c23b53827713d577cc9af32a55a6beeaeddce59dbceb5f53a3f87cb910609599
+DIST textX-4.2.0.gh.tar.gz 2136704 BLAKE2B 
c851a74deb7f79719549181b1e49201e60422007d600ff058b8c513d3cfbcfaad6d42a719425d16a7810662fe190ddbd65a23e75c8f8fca59b109c6be9046306
 SHA512 
d2342e7408dd51b5960e868d278ee5f4f656b4befad7f67ecac15e1c587d65b1894ecfadb7219c8c1a33c0945ba37eff638458b69f3dfa01626ab363eee99540

diff --git a/dev-python/textx/textx-4.2.0.ebuild 
b/dev-python/textx/textx-4.2.0.ebuild
new file mode 100644
index 000000000000..26f8d25a2dd4
--- /dev/null
+++ b/dev-python/textx/textx-4.2.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=textX-${PV}
+DESCRIPTION="Meta-language for DSL implementation inspired by Xtext"
+HOMEPAGE="
+       https://pypi.org/project/textX/
+       https://github.com/textX/textX/
+"
+SRC_URI="
+       https://github.com/textX/textX/archive/${PV}.tar.gz
+               -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+       >=dev-python/arpeggio-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               dev-python/html5lib[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+       cp -a "${BUILD_DIR}"/{install,test} || die
+       local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+       # Update the shebang
+       sed -e "s:install/usr/bin/${EPYTHON}:test/usr/bin/${EPYTHON}:" \
+               -i "${BUILD_DIR}"/test/usr/bin/textx || die
+
+       # Install necessary plugins
+       local plugins=(
+               tests/functional/subcommands/example_project
+               tests/functional/registration/projects/*
+       )
+       local p
+       for p in "${plugins[@]}"; do
+               pushd "${p}" >/dev/null || die
+               distutils_pep517_install "${BUILD_DIR}"/test
+               popd >/dev/null || die
+       done
+
+       epytest tests/functional
+}