commit: b2641ce70a8b74ea5782e5b14af3f883aa4f02cc
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 21 19:41:21 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 21 19:49:31 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b2641ce7
dev-python/isal: New package, v1.7.2
New test dependency for dev-python/aiohttp.
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/isal/Manifest | 1 +
dev-python/isal/isal-1.7.2.ebuild | 54 +++++++++++++++++++++++++++++++++++++++
dev-python/isal/metadata.xml | 11 ++++++++
3 files changed, 66 insertions(+)
diff --git a/dev-python/isal/Manifest b/dev-python/isal/Manifest
new file mode 100644
index 000000000000..b8491670e1fa
--- /dev/null
+++ b/dev-python/isal/Manifest
@@ -0,0 +1 @@
+DIST python-isal-1.7.2.gh.tar.gz 3396847 BLAKE2B
a92f2fb3bbf3786d0fdb15cf838d71dc9ae3f4870a50a6280ee31cd9f8277d603e144dd9af18d24eb98070f8368897ab2d3b7853b9a48dafbb5733c8851652be
SHA512
0c97a2ec72428d522d3afd3fc109183600c33f42328c71cc78c7c4e376d4c9a8fef5287830653b280712f8a5d67f46f4088f8deb1edfb57b6f4385dcc8744d52
diff --git a/dev-python/isal/isal-1.7.2.ebuild
b/dev-python/isal/isal-1.7.2.ebuild
new file mode 100644
index 000000000000..8edbdfddc595
--- /dev/null
+++ b/dev-python/isal/isal-1.7.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=python-isal-${PV}
+DESCRIPTION="Faster zlib and gzip via the ISA-L library"
+HOMEPAGE="
+ https://github.com/pycompression/python-isal/
+ https://pypi.org/project/isal/
+"
+# no tests in sdist, as of 1.7.2
+# https://github.com/pycompression/python-isal/issues/231
+SRC_URI="
+ https://github.com/pycompression/python-isal/archive/v${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+ dev-libs/isa-l:=
+"
+RDEPEND="
+ ${DEPEND}
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+ export PYTHON_ISAL_LINK_DYNAMIC=1
+
+ # why people can't use setuptools-scm...
+ sed -i -e '/versioningit/d' setup.py || die
+ sed -i -e 's/versioningit/ignoreme/' pyproject.toml || die
+ # it is an noeol file...
+ echo >> setup.cfg || die
+ echo "version = ${PV}" >> setup.cfg || die
+ echo "__version__ = '${PV}'" > src/isal/_version.py || die
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest tests
+}
diff --git a/dev-python/isal/metadata.xml b/dev-python/isal/metadata.xml
new file mode 100644
index 000000000000..1a43db6e476e
--- /dev/null
+++ b/dev-python/isal/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
+<pkgmetadata>
+ <maintainer type="project">
+ <email>[email protected]</email>
+ </maintainer>
+ <upstream>
+ <remote-id type="github">pycompression/python-isal</remote-id>
+ <remote-id type="pypi">isal</remote-id>
+ </upstream>
+</pkgmetadata>
