commit: 8c5e0a7fb574921499b2c25fdfdb5cbaa6b3b6b2
Author: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 3 15:07:09 2025 +0000
Commit: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Tue Jun 3 15:07:09 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8c5e0a7f
sys-apps/bolt: add 0.9.9
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>
sys-apps/bolt/Manifest | 1 +
sys-apps/bolt/bolt-0.9.9.ebuild | 84 +++++++++++++++++++++++++++++++++++++++++
2 files changed, 85 insertions(+)
diff --git a/sys-apps/bolt/Manifest b/sys-apps/bolt/Manifest
index d460a8973baa..52c7be4ad777 100644
--- a/sys-apps/bolt/Manifest
+++ b/sys-apps/bolt/Manifest
@@ -1 +1,2 @@
DIST bolt-0.9.8.tar.bz2 192836 BLAKE2B
7a06572562af5586d479fee58fb2469b8d804d6eafb41a52c5a575ef2acf616fb684b4e92181430444d67d9889c836bd6d96e1a6d3460cd01300f80d99876c04
SHA512
e9b2ccca66930ee40fd283b09e4bd2bffe1f496e4f898a9d4e069e673a2c9320d456b9ad4b33c4e3e26d25f363985a798c6c860c4c0b103558dbbab78f02ba2b
+DIST bolt-0.9.9.tar.bz2 193145 BLAKE2B
62038723349f9b234085693f6139b5d8e33efc84003aae346f47fbb9444ea564eab2a304ded598b12fe31e36be906771be1d7987ff60f016e7b305cbe4ebb4d6
SHA512
21214b325dc9a78a5096a9108a93e9dad1670b7400996a551ec4f62260e9253c50209bbc86ce2950348e5691ee9434114be890a6f34e2c9defe8c7308d7693de
diff --git a/sys-apps/bolt/bolt-0.9.9.ebuild b/sys-apps/bolt/bolt-0.9.9.ebuild
new file mode 100644
index 000000000000..33c7fae12a76
--- /dev/null
+++ b/sys-apps/bolt/bolt-0.9.9.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_1{0..4} )
+inherit linux-info python-any-r1 meson udev
+
+DESCRIPTION="Userspace system daemon to enable security levels for Thunderbolt
3"
+HOMEPAGE="https://gitlab.freedesktop.org/bolt/bolt";
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.bz2";
+
+LICENSE="LGPL-2.1 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~loong ~riscv ~x86"
+IUSE="selinux test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-libs/glib-2.56.0:2
+ virtual/libudev:=
+ virtual/udev
+ sys-auth/polkit[introspection]
+ selinux? ( sec-policy/selinux-thunderbolt )
+"
+DEPEND="
+ ${RDEPEND}
+ test? (
+ dev-util/umockdev
+ )
+"
+BDEPEND="
+ app-text/asciidoc
+ dev-util/glib-utils
+ virtual/pkgconfig
+ test? (
+ dev-util/umockdev
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep \
+ 'dev-python/pygobject[${PYTHON_USEDEP}]' \
+ 'dev-python/dbus-python[${PYTHON_USEDEP}]' \
+ 'dev-python/python-dbusmock[${PYTHON_USEDEP}]'
+ )
+ )
+"
+
+pkg_setup() {
+ if use kernel_linux && kernel_is lt 5 6; then
+ CONFIG_CHECK="~THUNDERBOLT"
+ ERROR_THUNDERBOLT="This package requires the thunderbolt kernel
driver."
+ else
+ CONFIG_CHECK="~USB4"
+ ERROR_USB4="This package requires the USB4 kernel driver for
Thunderbolt support."
+ fi
+ CONFIG_CHECK+=" ~HOTPLUG_PCI"
+ ERROR_HOTPLUG_PCI="Thunderbolt requires PCI hotplug support."
+
+ linux-info_pkg_setup
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dman=true
+ --sysconfdir="${EPREFIX}"/etc
+ --localstatedir="${EPREFIX}"/var
+ --sharedstatedir="${EPREFIX}"/var/lib
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ newinitd "${FILESDIR}"/${PN}.openrc-r1 boltd
+ keepdir /var/lib/boltd
+}
+
+pkg_postinst() {
+ udev_reload
+}
+
+pkg_postrm() {
+ udev_reload
+}
