commit: 83a5aa71d0091e40b328d8a5766bee800972d58b
Author: Petr Vaněk <arkamar <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 25 08:14:25 2025 +0000
Commit: Petr Vaněk <arkamar <AT> gentoo <DOT> org>
CommitDate: Fri Jul 25 08:21:39 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=83a5aa71
dev-libs/zziplib: add 0.13.80
Signed-off-by: Petr Vaněk <arkamar <AT> gentoo.org>
dev-libs/zziplib/Manifest | 1 +
dev-libs/zziplib/zziplib-0.13.80.ebuild | 74 +++++++++++++++++++++++++++++++++
2 files changed, 75 insertions(+)
diff --git a/dev-libs/zziplib/Manifest b/dev-libs/zziplib/Manifest
index c456d49c8ae9..c721c3a08184 100644
--- a/dev-libs/zziplib/Manifest
+++ b/dev-libs/zziplib/Manifest
@@ -1,2 +1,3 @@
DIST zziplib-0.13.74-testdata.tar.xz 166188 BLAKE2B
f3cc98495542fb95e8bd9cfb98ecd22c9e6206fd13c1d0607ee8b7640ddb3d3c4b9cb7bc7ca7a95a787ffef4e5a8c2b4ab1bc0c5890811ab21c681239840dcdb
SHA512
d4545f770c4f00658ec69a7f393f38d0c649704adb30b6a25f2c0b48711829416985258d34911d48b9bd394d9334ab89c8deda719f2aae509a75441f8a8d8902
DIST zziplib-0.13.79.tar.gz 1197706 BLAKE2B
007bac246222d766562860b383df0cefcfd0e99e02b805d74b9708c259b3f75ffbc9897edd4d7e18dfe96d5eee682177df9cd00b6821099fa19814af1f7a4f6d
SHA512
bed63fa7d430bd197bb70084f28ae6edc4c4120655b882bc8367f968b32c03340bb6d9bf1b14a5fcc5a1160d91ccf00e7b1131a4123da5d52233a84840ba8b7e
+DIST zziplib-0.13.80.tar.gz 1192948 BLAKE2B
88b686703225487c0131eef830a2a8ebd5947e9adffec766a6e150fe6010fc2a8d65141466e3db54767e8a622ceb7ff2a1acb2b602a3a70b01072e92dabd1f09
SHA512
1560b9b6851247ef07e64c689551e191eb26e2756f7ba32bdd1a7ed345a76b444050474b2fdd5f6308ca2ff1e9a55a55c8961eefaf8db0c6674c6a2f1c368a68
diff --git a/dev-libs/zziplib/zziplib-0.13.80.ebuild
b/dev-libs/zziplib/zziplib-0.13.80.ebuild
new file mode 100644
index 000000000000..58b4813ffd0b
--- /dev/null
+++ b/dev-libs/zziplib/zziplib-0.13.80.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# It's critical that we use RelWithDebInfo and not Release (which a user
+# may set) because the upstream CMake sets a different library name (!)
+# with Release.
+CMAKE_BUILD_TYPE=RelWithDebInfo
+PYTHON_COMPAT=( python3_{11..13} )
+# Needed for docs, bug #8357553
+PYTHON_REQ_USE="xml(+)"
+inherit cmake flag-o-matic python-any-r1
+
+TEST_PV="0.13.74"
+DESCRIPTION="Lightweight library for extracting data from files archived in a
single zip file"
+HOMEPAGE="https://github.com/gdraheim/zziplib https://zziplib.sourceforge.net";
+# Test data tarball generated with python ./zziptests.py -D -d /tmp/zziplib -v
+SRC_URI="
+ https://github.com/gdraheim/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+ test? (
https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${PN}-${TEST_PV}-testdata.tar.xz
)
+"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0/13"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="sdl test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ ${PYTHON_DEPS}
+ test? (
+ app-arch/unzip
+ app-arch/zip
+ )
+"
+DEPEND="
+ sys-libs/zlib
+ sdl? ( media-libs/libsdl2 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ # This test assumes being built with automake (checks for .libs/x).
+ sed -i -e 's/test_81000_zzshowme_check_sfx/skip_&/' test/zziptests.py
|| die
+ cmake_src_prepare
+}
+
+src_configure() {
+ #
https://github.com/gdraheim/zziplib/commit/f3bfc0dd6663b7df272cc0cf17f48838ad724a2f#diff-b7b1e314614cf326c6e2b6eba1540682R100
+ append-flags -fno-strict-aliasing
+
+ local mycmakeargs=(
+ -DZZIPSDL=$(usex sdl)
+ -DBUILD_TESTS=$(usex test)
+ -DZZIPTEST=$(usex test)
+ -DZZIPDOCS=ON
+ -DZZIPWRAP=OFF
+ )
+
+ cmake_src_configure
+}
+
+src_test() {
+ cd "${S}" || die
+ "${EPYTHON}" "${S}"/test/zziptests.py \
+ --downloads=no \
+ --verbose \
+ --topsrcdir "${S}" \
+ --bindir "$(realpath --relative-to="${S}" "${BUILD_DIR}"/bins)"
\
+ --downloaddir "${WORKDIR}"/${PN}-${TEST_PV}-testdata \
+ --testdatadir "${T}"/testdata.d \
+ || die "Tests failed with ${EPYTHON}"
+}
