commit: 56700b53d7935e96ab082411aee5cf7cbf6cd93e
Author: Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 30 07:29:17 2025 +0000
Commit: Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Wed Jul 30 08:53:01 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=56700b53
media-video/obs-studio: add 31.1.2
Upstream changes include, but are not limited to, various PipeWire
related fixes.
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>
media-video/obs-studio/Manifest | 1 +
media-video/obs-studio/obs-studio-31.1.2.ebuild | 277 ++++++++++++++++++++++++
2 files changed, 278 insertions(+)
diff --git a/media-video/obs-studio/Manifest b/media-video/obs-studio/Manifest
index b8fdd8dd62f1..bf2e30a0be16 100644
--- a/media-video/obs-studio/Manifest
+++ b/media-video/obs-studio/Manifest
@@ -8,5 +8,6 @@ DIST
obs-browser-bdabf8300ecefeb566b81f4a7ff75f8a8e21f62b.tar.gz 117046 BLAKE2B
DIST obs-studio-31.0.4.tar.gz 16034249 BLAKE2B
93f928ec576fa78a9b31582b4b143c0b3d2709489d3d1cf9ccce731ae03ca3218e96580805643938bb759395bd8ccae4d8106ba1cbf9bc91c6a8c457ea4024a0
SHA512
416ec3f71c954dc6509381133924331b9538b9c4d9572a19a251fa3925bc84360ded47d694b9ed546e1f075264fa685fa98bcc440c57db37a88c78da6b0b46c9
DIST obs-studio-31.1.0.tar.gz 16121035 BLAKE2B
eb1aed5cc1d685ce6c87288203acf4e7159a8fa051170958b453b5a9f713bc8f963bc6929fccbcfed1e6618ab6a70567200758f349220f7df14b384d8e89af60
SHA512
abaf4090baf121fcf471bf025085f42d8bea8ae9de037e6d32f58910993886341cdd11f3f61a7608a1bce06f12cde78d3d6d0dc5c9fd0320b8d59e166df17d41
DIST obs-studio-31.1.1.tar.gz 16122183 BLAKE2B
14c46b3ec0fb29fbc8f7facbd82245cfe087ec31b13f2508c1519e47d594f086e9e5e7873bf3c8e55ab9c584dd11304b68a2c6d460cd66f13236167331797e61
SHA512
04d9361276ce2e2a42fa886812715f654df4f6d099d60357b26b584347dc1e4c0fe15c1425a11b8c0a48a00726e2590f848a0b6cb13e53180e9385d72222c627
+DIST obs-studio-31.1.2.tar.gz 16120746 BLAKE2B
3df373f4dfae3502e9f12f4b330423e9615c87de401adec5fe174f52533b1fc99d3f0134d895d5535d7112ed5be69aad0105129e0aeeee44e4668841a485c466
SHA512
bee52406c2a0a2a1935d81e6eed76d6120d22c5b213bb807bfa414b6b063eb0a0ab0a6ad08db936bc0eadc0fa98a2d1adf18ff87fcc63472cb6a82c4b4f565ed
DIST obs-websocket-40d26dbf4d29137bf88cd393a3031adb04d68bba.tar.gz 254383
BLAKE2B
ccf4af62844a05c35083028d974c5cbd631e22e91e9d2a7dace75ca4543a85f2c32b0868a46545fe3c1b9bf2b20ec577517e262b14ad9a0da1ab02786f95989b
SHA512
1436bca2110e46377b03fafa2711712959427e37d4bf96431e35f23c048dff53ab0c81d4607bcb01f9899ff3a5748e2ea9b7ee2b5fb88891ab05d55e1649e99b
DIST obs-websocket-c542622d7b6d41ce5875f54efdab1d4ac2967ef4.tar.gz 250604
BLAKE2B
9f41a623ba0b27b4ac2a7e315bcd51e9d625636d16d98c855b9d62ed0eb8e90c1fa1ef8532a2c865af202296458e0c8c83751f1883b2100d1f553e1289328994
SHA512
3b22fc6b48a048ca3b29d52a8cf36218f686c6c09540aa104b183b128f39c2dcd532f6b91b01b71b058905ae62b6304d8bfb4ed982ed69ccc457cb1a6dd8e278
diff --git a/media-video/obs-studio/obs-studio-31.1.2.ebuild
b/media-video/obs-studio/obs-studio-31.1.2.ebuild
new file mode 100644
index 000000000000..c76c072a7e6e
--- /dev/null
+++ b/media-video/obs-studio/obs-studio-31.1.2.ebuild
@@ -0,0 +1,277 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_REMOVE_MODULES_LIST=( FindMbedTLS )
+LUA_COMPAT=( luajit )
+# For the time being upstream supports up to Python 3.12 only.
+# Any issues found with 3.13+ should be reported as a Gentoo bug.
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit cmake flag-o-matic lua-single optfeature python-single-r1 xdg
+
+CEF_AMD64="cef_binary_6533_linux_x86_64_v5"
+CEF_ARM64="cef_binary_6533_linux_aarch64_v5"
+OBS_BROWSER_COMMIT="bdabf8300ecefeb566b81f4a7ff75f8a8e21f62b"
+OBS_WEBSOCKET_COMMIT="40d26dbf4d29137bf88cd393a3031adb04d68bba"
+
+DESCRIPTION="Software for Recording and Streaming Live Video Content"
+HOMEPAGE="https://obsproject.com";
+
+if [[ ${PV} == 9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git";
+ EGIT_SUBMODULES=(
+ plugins/obs-browser
+ plugins/obs-websocket
+ )
+else
+ SRC_URI="
+ https://github.com/obsproject/${PN}/archive/${PV}.tar.gz
+ -> ${P}.tar.gz
+
https://github.com/obsproject/obs-browser/archive/${OBS_BROWSER_COMMIT}.tar.gz
+ -> obs-browser-${OBS_BROWSER_COMMIT}.tar.gz
+
https://github.com/obsproject/obs-websocket/archive/${OBS_WEBSOCKET_COMMIT}.tar.gz
+ -> obs-websocket-${OBS_WEBSOCKET_COMMIT}.tar.gz
+ "
+ KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+SRC_URI+="
+ browser? (
+ amd64? (
https://cdn-fastly.obsproject.com/downloads/${CEF_AMD64}.tar.xz )
+ arm64? (
https://cdn-fastly.obsproject.com/downloads/${CEF_ARM64}.tar.xz )
+ )
+"
+
+LICENSE="Boost-1.0 GPL-2+ MIT Unlicense"
+SLOT="0"
+IUSE="
+ +alsa browser decklink fdk jack lua mpegts nvenc pipewire pulseaudio
+ python qsv sndio speex test-input truetype v4l vlc wayland websocket
+"
+REQUIRED_USE="
+ browser? ( || ( alsa pulseaudio ) )
+ lua? ( ${LUA_REQUIRED_USE} )
+ python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+BDEPEND="
+ kde-frameworks/extra-cmake-modules:0
+ lua? ( dev-lang/swig )
+ python? ( dev-lang/swig )
+"
+# media-video/ffmpeg[opus] required due to bug 909566
+# The websocket plug-in fails to build with 'dev-cpp/asio-1.34.0':
+# https://github.com/obsproject/obs-websocket/issues/1291
+DEPEND="
+ dev-cpp/nlohmann_json
+ dev-libs/glib:2
+ dev-libs/jansson:=
+ dev-libs/uthash
+ dev-qt/qtbase:6[network,widgets,X,xml(+)]
+ dev-qt/qtsvg:6
+ media-libs/libglvnd[X]
+ media-libs/libva
+ media-libs/rnnoise
+ media-libs/x264:=
+ >=media-video/ffmpeg-6.1:=[nvenc?,opus,x264]
+ net-misc/curl
+ net-libs/mbedtls:3=
+ sys-apps/dbus
+ sys-apps/pciutils
+ sys-apps/util-linux
+ sys-libs/zlib:=
+ x11-libs/libdrm
+ x11-libs/libX11
+ x11-libs/libxcb:=
+ x11-libs/libXcomposite
+ x11-libs/libXfixes
+ x11-libs/libxkbcommon
+ alsa? ( media-libs/alsa-lib )
+ browser? (
+ >=app-accessibility/at-spi2-core-2.46.0:2
+ dev-libs/expat
+ dev-libs/glib
+ dev-libs/nspr
+ dev-libs/nss
+ media-libs/alsa-lib
+ media-libs/fontconfig
+ media-libs/mesa[gbm(+)]
+ net-print/cups
+ x11-libs/cairo
+ x11-libs/libXcursor
+ x11-libs/libXdamage
+ x11-libs/libXext
+ x11-libs/libXi
+ x11-libs/libxkbcommon
+ x11-libs/libXrandr
+ x11-libs/libXrender
+ x11-libs/libXScrnSaver
+ x11-libs/libxshmfence
+ x11-libs/libXtst
+ x11-libs/pango
+ )
+ fdk? ( media-libs/fdk-aac:= )
+ jack? ( virtual/jack )
+ lua? ( ${LUA_DEPS} )
+ mpegts? (
+ net-libs/librist
+ net-libs/srt
+ )
+ nvenc? ( >=media-libs/nv-codec-headers-12 )
+ pipewire? ( media-video/pipewire:= )
+ pulseaudio? ( media-libs/libpulse )
+ python? ( ${PYTHON_DEPS} )
+ qsv? ( media-libs/libvpl )
+ sndio? ( media-sound/sndio )
+ speex? ( media-libs/speexdsp )
+ truetype? (
+ media-libs/fontconfig
+ media-libs/freetype
+ )
+ v4l? (
+ media-libs/libv4l
+ virtual/udev
+ )
+ vlc? ( media-video/vlc:= )
+ wayland? (
+ dev-libs/wayland
+ x11-libs/libxkbcommon
+ )
+ websocket? (
+ <dev-cpp/asio-1.34.0
+ dev-cpp/websocketpp
+ dev-libs/qr-code-generator
+ )
+"
+RDEPEND="${DEPEND}"
+
+QA_PREBUILT="
+ usr/lib*/obs-plugins/chrome-sandbox
+ usr/lib*/obs-plugins/libcef.so
+ usr/lib*/obs-plugins/libEGL.so
+ usr/lib*/obs-plugins/libGLESv2.so
+ usr/lib*/obs-plugins/libvk_swiftshader.so
+ usr/lib*/obs-plugins/libvulkan.so.1
+ usr/lib*/obs-plugins/swiftshader/libEGL.so
+ usr/lib*/obs-plugins/swiftshader/libGLESv2.so
+"
+
+pkg_setup() {
+ use lua && lua-single_pkg_setup
+ use python && python-single-r1_pkg_setup
+}
+
+src_unpack() {
+ default
+
+ if [[ ${PV} == 9999 ]]; then
+ git-r3_src_unpack
+ else
+ rm -d ${P}/plugins/obs-browser || die
+ mv obs-browser-${OBS_BROWSER_COMMIT} ${P}/plugins/obs-browser
|| die
+
+ rm -d ${P}/plugins/obs-websocket || die
+ mv obs-websocket-${OBS_WEBSOCKET_COMMIT}
${P}/plugins/obs-websocket || die
+ fi
+}
+
+src_prepare() {
+ default
+
+ # -Werror=lto-type-mismatch
+ # https://bugs.gentoo.org/867250
+ # https://github.com/obsproject/obs-studio/issues/8988
+ use wayland && filter-lto
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ local libdir=$(get_libdir)
+ local mycmakeargs=(
+ -DENABLE_ALSA=$(usex alsa)
+ -DENABLE_AJA=OFF
+ -DENABLE_BROWSER=$(usex browser)
+ -DENABLE_CCACHE=OFF
+ -DENABLE_DECKLINK=$(usex decklink)
+ -DENABLE_FFMPEG_NVENC=$(usex nvenc)
+ -DENABLE_FREETYPE=$(usex truetype)
+ -DENABLE_JACK=$(usex jack)
+ -DENABLE_LIBFDK=$(usex fdk)
+ -DENABLE_NEW_MPEGTS_OUTPUT=$(usex mpegts)
+ -DENABLE_NVENC=$(usex nvenc)
+ -DENABLE_PIPEWIRE=$(usex pipewire)
+ -DENABLE_PULSEAUDIO=$(usex pulseaudio)
+ -DENABLE_QSV11=$(usex qsv)
+ -DENABLE_RNNOISE=ON
+ -DENABLE_SNDIO=$(usex sndio)
+ -DENABLE_SPEEXDSP=$(usex speex)
+ -DENABLE_TEST_INPUT=$(usex test-input)
+ -DENABLE_V4L2=$(usex v4l)
+ -DENABLE_VLC=$(usex vlc)
+ -DENABLE_VST=ON
+ -DENABLE_WAYLAND=$(usex wayland)
+ -DENABLE_WEBRTC=OFF # Requires libdatachannel.
+ -DENABLE_WEBSOCKET=$(usex websocket)
+ )
+
+ if [[ ${PV} != 9999 ]]; then
+ mycmakeargs+=(
+ -DOBS_VERSION_OVERRIDE=${PV}
+ )
+ fi
+
+ if use lua || use python; then
+ mycmakeargs+=(
+ -DENABLE_SCRIPTING_LUA=$(usex lua)
+ -DENABLE_SCRIPTING_PYTHON=$(usex python)
+ -DENABLE_SCRIPTING=ON
+ )
+ else
+ mycmakeargs+=( -DENABLE_SCRIPTING=OFF )
+ fi
+
+ if use browser; then
+ use amd64 && mycmakeargs+=(
-DCEF_ROOT_DIR=../cef_binary_6533_linux_x86_64 )
+ use arm64 && mycmakeargs+=(
-DCEF_ROOT_DIR=../cef_binary_6533_linux_aarch64 )
+ mycmakeargs+=( -DENABLE_WHATSNEW=ON )
+ else
+ mycmakeargs+=( -DENABLE_WHATSNEW=OFF )
+ fi
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ # external plugins may need some things not installed by default,
install them here
+ insinto /usr/include/obs/frontend/api
+ doins frontend/api/obs-frontend-api.h
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ if ! use alsa && ! use pulseaudio; then
+ elog
+ elog "For the audio capture features to be available,"
+ elog "at least one of the 'alsa' or 'pulseaudio' USE-flags
needs to"
+ elog "be enabled."
+ elog
+ fi
+
+ if use v4l && has_version media-video/v4l2loopback; then
+ elog
+ elog "Depending on system configuration, the v4l2loopback
kernel module"
+ elog "may need to be loaded manually, and needs to be re-built
after"
+ elog "kernel changes."
+ elog
+ fi
+
+ optfeature "VA-API hardware encoding" media-video/ffmpeg[vaapi]
+ optfeature "virtual camera support" media-video/v4l2loopback
+}
