commit: ab6b0c1e3e2f3415b74e9d145ebe46cc52190190
Author: Luca Barbato <lu_zero <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 27 17:23:27 2025 +0000
Commit: Luca Barbato <lu_zero <AT> gentoo <DOT> org>
CommitDate: Sat Sep 27 17:25:42 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ab6b0c1e
sys-apps/uutils-coreutils: add 0.2.2
Signed-off-by: Luca Barbato <lu_zero <AT> gentoo.org>
sys-apps/uutils-coreutils/Manifest | 2 +
.../uutils-coreutils/uutils-coreutils-0.2.2.ebuild | 114 +++++++++++++++++++++
2 files changed, 116 insertions(+)
diff --git a/sys-apps/uutils-coreutils/Manifest
b/sys-apps/uutils-coreutils/Manifest
index a1f4edf1963b..ddfb4c8aab4e 100644
--- a/sys-apps/uutils-coreutils/Manifest
+++ b/sys-apps/uutils-coreutils/Manifest
@@ -1,2 +1,4 @@
DIST coreutils-0.1.0-crates.tar.xz 19825496 BLAKE2B
9f746cbe086f92f60ef11477030ce84a0da38deb2d1ceab9a6cb5dfbf5433713463ae7e6d7cb81599dea9da3eff0d6dabdbd49c20a941ff93174d71e43ad935c
SHA512
fad27d419a32706026e536cd0db85bb492ffd4cc8f924c450c4498657e5680598d39a95268af5f3ec2fb6ca5d76c9e79d01bd5872df8333fd0165cf89e5929a6
+DIST coreutils-0.2.2-crates.tar.xz 21799080 BLAKE2B
b50758e5eff69d5a98e80c3ce888e85b081ce208a14706340843bfd4bd14f386af8275cca82d4f5168bb7634a16eb39c9cc08200d6831b119831e17ea4e997e0
SHA512
1f76735ed983496d489654798e86d85c52d1b0d67b2314e6c58453da8a267dceaf82e943f2a22b16c8775f72fe8cf05bea4be719bee9d47ee7cf29879d35619a
DIST uutils-coreutils-0.1.0.tar.gz 2511132 BLAKE2B
7e467037588a0b13a76a64bb185793305c1a993bd761a463b7d2041f27ccef50482c18017512b51cf58ca22c17076c79a3535486bde2015e56d170a5c64fe820
SHA512
e9b3941573b2267e6a4b17c49a64d71234e4cbf067f1180fe14bfe48012c9d400741067f6231855a6132f93138eb4bbcb1e970e98c5f937f8d3a5e5bc019f03c
+DIST uutils-coreutils-0.2.2.tar.gz 2827753 BLAKE2B
ca57fff4952c112459bc62ea56f3fa45f18b4dcdc2c0220c5609eeb8d0523a2f137f6aaf3ed918dbe9eb8efe1dce0de5056b37eedaf1756ff48b157bbde83765
SHA512
58def9fe8f01640c6eb7c16cd182061bf62fab22124bdedcb931cdb39b25c2bd3f31523561e321a4822d9e09107dc0c5cc2ddf8e20333138ddaa19d284db609f
diff --git a/sys-apps/uutils-coreutils/uutils-coreutils-0.2.2.ebuild
b/sys-apps/uutils-coreutils/uutils-coreutils-0.2.2.ebuild
new file mode 100644
index 000000000000..979a0cd568c6
--- /dev/null
+++ b/sys-apps/uutils-coreutils/uutils-coreutils-0.2.2.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Autogenerated by pycargoebuild 0.6.2
+
+EAPI=8
+
+CRATES="
+"
+
+RUST_MIN_VER="1.85.0"
+LLVM_COMPAT=( {17..20} )
+inherit cargo flag-o-matic llvm-r1 multiprocessing
+
+DESCRIPTION="GNU coreutils rewritten in Rust"
+HOMEPAGE="https://uutils.github.io/coreutils/
https://github.com/uutils/coreutils";
+
+if [[ ${PV} == 9999 ]] ; then
+ EGIT_REPO_URI="https://github.com/uutils/coreutils";
+ inherit git-r3
+elif [[ ${PV} == *_p* ]] ; then
+ COREUTILS_COMMIT=""
+
SRC_URI="https://github.com/uutils/coreutils/archive/${COREUTILS_COMMIT}.tar.gz
-> ${P}.tar.gz"
+ S="${WORKDIR}"/coreutils-${COREUTILS_COMMIT}
+else
+
SRC_URI="https://github.com/uutils/coreutils/archive/refs/tags/${PV}.tar.gz ->
${P}.tar.gz"
+ S="${WORKDIR}"/coreutils-${PV}
+
+ KEYWORDS="~amd64 ~arm64 ~ppc64"
+fi
+
+SRC_URI+="
+
https://github.com/gentoo-crate-dist/coreutils/releases/download/${PV}/coreutils-${PV}-crates.tar.xz
+"
+
+LICENSE="MIT"
+# Dependent crate licenses
+LICENSE+="
+ Apache-2.0 BSD-2 BSD Boost-1.0 CC0-1.0 ISC MIT Unicode-3.0 ZLIB
+"
+SLOT="0"
+IUSE="debug selinux test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+ dev-libs/oniguruma:=
+ selinux? ( sys-libs/libselinux )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+ test? ( dev-util/cargo-nextest )
+ selinux? (
+ $(llvm_gen_dep '
+ llvm-core/clang:${LLVM_SLOT}
+ ')
+ )
+"
+QA_FLAGS_IGNORED=".*"
+
+src_unpack() {
+ if [[ ${PV} == 9999 ]] ; then
+ git-r3_src_unpack
+ cargo_live_src_unpack
+ else
+ cargo_src_unpack
+ fi
+}
+
+src_compile() {
+ # normally cargo_src_compile sets this for us, but we don't use it
+ filter-lto
+
+ # By default, the crate uses a system version if it can. This just
guarantees
+ # that it will error out instead of building a vendored copy.
+ export RUSTONIG_SYSTEM_LIBONIG=1
+
+ makeargs=(
+ # Disable output synchronisation as make calls cargo
+ -Onone
+
+ V=1
+
+ PROFILE=$(usex debug debug release)
+
+ PREFIX="${EPREFIX}/usr"
+ PROG_PREFIX="uu-"
+ MULTICALL=y
+ MANDIR="/share/man/man1"
+
+ SELINUX_ENABLED=$(usex selinux 1 0)
+
+ # pinky, uptime, users, and who require utmpx (not available on
musl)
+ # bug #832868
+ # runcon chcon require selinux, but upstream broke the
SELINUX_ENABLED logic
+ SKIP_UTILS="$(usev elibc_musl "pinky uptime users who") $(usev
!selinux "runcon chcon")"
+ )
+
+ emake "${makeargs[@]}"
+}
+
+src_test() {
+ local -x RUST_BACKTRACE=full
+ local -x NEXTEST_TEST_THREADS="$(makeopts_jobs)"
+
+ # Nicer output for nextest vs test
+ emake "${makeargs[@]}" \
+ CARGOFLAGS="${CARGOFLAGS} $(usev !debug --release)" \
+ TEST_NO_FAIL_FAST="--no-fail-fast" \
+ nextest
+}
+
+src_install() {
+ emake "${makeargs[@]}" DESTDIR="${D}" install
+}
