commit: 877877b6d403942f18e4d58c110f558950f37c85
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 2 03:08:32 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 2 03:31:30 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=877877b6
dev-python/m2crypto: Bump to 0.46.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/m2crypto/Manifest | 1 +
dev-python/m2crypto/m2crypto-0.46.0.ebuild | 71 ++++++++++++++++++++++++++++++
2 files changed, 72 insertions(+)
diff --git a/dev-python/m2crypto/Manifest b/dev-python/m2crypto/Manifest
index 6fea549c63d5..cacb69063559 100644
--- a/dev-python/m2crypto/Manifest
+++ b/dev-python/m2crypto/Manifest
@@ -1 +1,2 @@
DIST m2crypto-0.45.1.tar.gz 363721 BLAKE2B
a2e1d78e65825e8ae13196aed8ea902618536a3607670a1b4900fbe5cd893d5badfd0431f6b594a209e49088ffbf6ea3540863a6ee2162ac230742d442322262
SHA512
7915bbb63625f645b6281dbdd2bb60691a6fa0d54ab505a1105d76efad5e0407ce68e38bebd5e0b0773bcbb99025ff7aa7d8df25fe32364d4a33471e6e9466ce
+DIST m2crypto-0.46.0.tar.gz 500661 BLAKE2B
247d92a8c5c285f7cff1d1917e40ed5e0c28b061e22689925712a332cb6e700de82956787360ce8fb09ea9099d7b265eca71ca1e76244e833a8fb279bc7da24c
SHA512
3505989cc2973640837a677cdb14511a15402816a2ce0217f43e2220c237f3c812909c561b94afe702ad3e6b7783f27a977ef1ef8d8cdf698c6a27a6768487ac
diff --git a/dev-python/m2crypto/m2crypto-0.46.0.ebuild
b/dev-python/m2crypto/m2crypto-0.46.0.ebuild
new file mode 100644
index 000000000000..10e65e03cf28
--- /dev/null
+++ b/dev-python/m2crypto/m2crypto-0.46.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2018-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+PYPI_PN="M2Crypto"
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="A Python crypto and SSL toolkit"
+HOMEPAGE="
+ https://sr.ht/~mcepl/m2crypto/
+ https://gitlab.com/m2crypto/m2crypto/
+ https://pypi.org/project/M2Crypto/
+"
+
+# openssl via src/SWIG/_lib11_compat.i
+LICENSE="BSD-2 openssl"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="abi_mips_n32 abi_mips_n64 abi_mips_o32"
+
+DEPEND="
+ dev-libs/openssl:=
+"
+RDEPEND="
+ ${DEPEND}
+"
+BDEPEND="
+ >=dev-lang/swig-2.0.9
+"
+
+swig_define() {
+ local x
+ for x; do
+ if tc-cpp-is-true "defined(${x})"; then
+ SWIG_FEATURES+=" -D${x}"
+ fi
+ done
+}
+
+src_prepare() {
+ # relies on very exact clock behavior which apparently fails
+ # with inconvenient CONFIG_HZ*
+ sed -e 's:test_server_simple_timeouts:_&:' \
+ -i tests/test_ssl.py || die
+ distutils-r1_src_prepare
+}
+
+python_compile() {
+ # setup.py looks at platform.machine() to determine swig options.
+ # For exotic ABIs, we need to give swig a hint.
+ local -x SWIG_FEATURES=
+
+ # https://bugs.gentoo.org/617946
+ swig_define __ILP32__
+
+ # https://bugs.gentoo.org/674112
+ swig_define __ARM_PCS_VFP
+
+ distutils-r1_python_compile
+}
+
+python_test() {
+ "${EPYTHON}" -m unittest -b -v tests.alltests.suite ||
+ die "Tests failed for ${EPYTHON}"
+}
