commit: 179eb93e819eee489442184e9abc25d23a28e484
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 30 06:09:56 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 30 06:44:57 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=179eb93e
dev-python/aws-xray-sdk: Bump to 2.15.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/aws-xray-sdk/Manifest | 1 +
dev-python/aws-xray-sdk/aws-xray-sdk-2.15.0.ebuild | 92 ++++++++++++++++++++++
2 files changed, 93 insertions(+)
diff --git a/dev-python/aws-xray-sdk/Manifest b/dev-python/aws-xray-sdk/Manifest
index 71721528c17e..c69a4ccb455f 100644
--- a/dev-python/aws-xray-sdk/Manifest
+++ b/dev-python/aws-xray-sdk/Manifest
@@ -1 +1,2 @@
DIST aws-xray-sdk-python-2.14.0.gh.tar.gz 276813 BLAKE2B
ce9a6c8a3b9acd4cb1e538c75702bebc1e392d350a999e8c609ddb900acadd0ecef11b2ce326786a64a73de3d84b0e18e6f4dd4ad91ece6a13283d727039925c
SHA512
e9f7a299e35741a63de999dbd4931b82aab97b4c690e9abec4d25106a4a1b1dbbda605b7ec8541000f97cdcf17fed1283abf8d561db63cc4ac1ed11405458f29
+DIST aws-xray-sdk-python-2.15.0.gh.tar.gz 278754 BLAKE2B
11df5a272c42b0349d18f57adf60c9ec7f067f18c13b976cb394639d8bc72fe342a33b727c30b2f8875179a15201f339688e1f714fa5b8cff136291acb832ad3
SHA512
a9529e9d671f57929c637a67adcabc84fcd1b4116db59106b5e9ca484dcffe2b570fe21caa28f5687ad1577141b193b4aa157082ea1d93a131b6d54305944d53
diff --git a/dev-python/aws-xray-sdk/aws-xray-sdk-2.15.0.ebuild
b/dev-python/aws-xray-sdk/aws-xray-sdk-2.15.0.ebuild
new file mode 100644
index 000000000000..0a6c5dbf8159
--- /dev/null
+++ b/dev-python/aws-xray-sdk/aws-xray-sdk-2.15.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=aws-xray-sdk-python-${PV}
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="
+ https://github.com/aws/aws-xray-sdk-python/
+ https://pypi.org/project/aws-xray-sdk/
+"
+SRC_URI="
+ https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+ >=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+ dev-python/wrapt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/bottle[${PYTHON_USEDEP}]
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ dev-python/webtest[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+ local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+ local -x AWS_SECRET_ACCESS_KEY=fake_key
+ local -x AWS_ACCESS_KEY_ID=fake_id
+
+ local EPYTEST_DESELECT=(
+ # Internet access
+ tests/test_patcher.py::test_external_file
+ tests/test_patcher.py::test_external_module
+ tests/test_patcher.py::test_external_submodules_full
+ tests/test_patcher.py::test_external_submodules_ignores_file
+ tests/test_patcher.py::test_external_submodules_ignores_module
+ # benchmark
+ tests/test_local_sampling_benchmark.py
+ # Fails, probably because above is ignored
+ tests/test_async_local_storage.py::test_localstorage_isolation
+ tests/test_async_recorder.py::test_capture
+ tests/test_async_recorder.py::test_concurrent_calls
+ tests/test_async_recorder.py::test_async_context_managers
+ # connects to local mysqld
+
tests/ext/sqlalchemy_core/test_dburl.py::test_db_url_with_special_char
+ # TODO
+ tests/test_lambda_context.py::test_disable
+ tests/test_lambda_context.py::test_facade_segment_generation
+ tests/test_lambda_context.py::test_put_subsegment
+ )
+ local EPYTEST_IGNORE=(
+ # unpackaged deps
+ tests/ext/aiobotocore
+ tests/ext/pg8000
+ tests/ext/psycopg
+ tests/ext/psycopg2
+ tests/ext/pymysql
+ tests/ext/pynamodb
+ tests/ext/sqlalchemy_core/test_postgres.py
+ tests/ext/django/test_db.py
+ # Internet access
+ tests/ext/httplib
+ tests/ext/httpx
+ tests/ext/requests
+ # requires old package vesions
+ tests/ext/aiohttp
+ tests/ext/django
+ tests/ext/flask_sqlalchemy
+ tests/ext/sqlalchemy
+ )
+
+ epytest
+}
