commit: f6ad6e0941a594aa421a433630a204d11a434206
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 4 06:26:45 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Nov 4 06:49:50 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f6ad6e09
dev-python/hishel: Bump to 1.1.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hishel/Manifest | 1 +
dev-python/hishel/hishel-1.1.2.ebuild | 73 +++++++++++++++++++++++++++++++++++
2 files changed, 74 insertions(+)
diff --git a/dev-python/hishel/Manifest b/dev-python/hishel/Manifest
index e532646fbf2d..b7c517f4ce12 100644
--- a/dev-python/hishel/Manifest
+++ b/dev-python/hishel/Manifest
@@ -1,2 +1,3 @@
DIST hishel-0.1.5.gh.tar.gz 1065622 BLAKE2B
926801f579a57cc2b45cb6cd5326459493452d34b32a2725b906307dcc4575b1297b35ffc626e51acc5805216731552d58c672dedb0541f2c771f153daee960d
SHA512
b1f850895b147da616ace381d98ac9b6a15386d7e79d64a57a4e87f9bd0b42009a6ffa15fe1f8e46c57f8bc664c3af97d46e5adb81211e30fae87dab898f7734
DIST hishel-1.1.1.gh.tar.gz 1096020 BLAKE2B
aa575b65be1f95905c789ffc8159c81d7c39a30b8f8f2e3f85983e4f0d7a47b13b5953bf08fc53fb81116d2fe6f7735daef88fc623abb1f2e8c7d7df25b17670
SHA512
cd6e90695cfd4194306432cf8adaf2a7adc3f44bbe6ccb31b6a651f07eb0ccb6ea16641f1c4b6f0f3a5198a8a891ebedce051e597613d8d8ab5028e95328e2e6
+DIST hishel-1.1.2.gh.tar.gz 1097284 BLAKE2B
230bde8f23bea76a6741c7030c63b0eb10698f99092010044d7b269673f9c1426a9aa8e268261bfe0634d318f361d5a87578c056842ab294296e2f9afc73c900
SHA512
49d956184421da99ae89f047023fbe3584a3e5623cd07d288e1b4759969be73b7de07020712b5b57117ffe95385ca14a4bea346e2a3beecc024f6fdb1df71436
diff --git a/dev-python/hishel/hishel-1.1.2.ebuild
b/dev-python/hishel/hishel-1.1.2.ebuild
new file mode 100644
index 000000000000..e93e371f4a64
--- /dev/null
+++ b/dev-python/hishel/hishel-1.1.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="An elegant HTTP Cache implementation for HTTPX and HTTP Core"
+HOMEPAGE="
+ https://github.com/karpetrosyan/hishel/
+ https://pypi.org/project/hishel/
+"
+SRC_URI="
+ https://github.com/karpetrosyan/${PN}/archive/refs/tags/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+ >=dev-python/anyio-4.9.0[${PYTHON_USEDEP}]
+ >=dev-python/anysqlite-0.0.5[${PYTHON_USEDEP}]
+ >=dev-python/httpx-0.28.1[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-1.1.2[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-1.14.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ ${RDEPEND}
+ dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+ test? (
+ dev-db/redis
+ >=dev-python/boto3-1.15.3[${PYTHON_USEDEP}]
+ >=dev-python/inline-snapshot-0.28.0[${PYTHON_USEDEP}]
+ >=dev-python/redis-6.2.0[${PYTHON_USEDEP}]
+ >=dev-python/time-machine-2.19.0[${PYTHON_USEDEP}]
+ >=dev-python/trio-0.30.0[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=( anyio )
+distutils_enable_tests pytest
+
+src_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/test_async_httpx.py
+ tests/test_requests.py
+ tests/test_sync_httpx.py
+ )
+
+ local redis_pid="${T}"/redis.pid
+ local redis_port=6379
+
+ einfo "Starting Redis"
+ "${EPREFIX}"/usr/sbin/redis-server - <<- EOF
+ daemonize yes
+ pidfile ${redis_pid}
+ port ${redis_port}
+ bind 127.0.0.1 ::1
+ EOF
+
+ # Run the tests
+ distutils-r1_src_test
+
+ # Clean up afterwards
+ kill "$(<"${redis_pid}")" || die
+}
