commit: 74a03bbae5a113b105d99542dd1666333c3527ab
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 13 12:17:56 2025 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Nov 13 12:24:48 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=74a03bba
app-backup/duplicity: add 9999
Upstream often ask people to test dev releases for bug reports.
Signed-off-by: Sam James <sam <AT> gentoo.org>
app-backup/duplicity/duplicity-9999.ebuild | 72 ++++++++++++++++++++++++++++++
1 file changed, 72 insertions(+)
diff --git a/app-backup/duplicity/duplicity-9999.ebuild
b/app-backup/duplicity/duplicity-9999.ebuild
new file mode 100644
index 000000000000..6b72e1fb4daa
--- /dev/null
+++ b/app-backup/duplicity/duplicity-9999.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+
+inherit distutils-r1
+
+DESCRIPTION="Secure backup system using gnupg to encrypt data"
+HOMEPAGE="https://duplicity.gitlab.io/";
+
+if [[ ${PV} == 9999 ]] ; then
+ EGIT_REPO_URI="https://gitlab.com/duplicity/duplicity.git/";
+ inherit git-r3
+else
+
SRC_URI="https://gitlab.com/duplicity/duplicity/-/archive/rel.${PV}/${PN}-rel.${PV}.tar.bz2";
+ S="${WORKDIR}"/${PN}-rel.${PV}
+
+ KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="s3 test"
+
+COMMON_DEPEND="
+ net-libs/librsync
+ app-crypt/gnupg
+ dev-python/fasteners[${PYTHON_USEDEP}]
+"
+DEPEND="
+ ${COMMON_DEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/setuptools-scm[${PYTHON_USEDEP}]
+ test? (
+ || ( app-arch/par2cmdline app-arch/par2cmdline-turbo )
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ )
+"
+RDEPEND="
+ ${COMMON_DEPEND}
+ dev-python/paramiko[${PYTHON_USEDEP}]
+ s3? ( dev-python/boto3[${PYTHON_USEDEP}] )
+"
+
+EPYTEST_DESELECT=(
+ # Linting tests (black, pylint, etc); not relevant for us
+ testing/test_code.py::CodeTest::test_black
+ testing/test_code.py::CodeTest::test_pep8
+ testing/test_code.py::CodeTest::test_pylint
+ # boto3
+ testing/unit/test_cli_main.py::CommandlineTest::test_intermixed_args
+)
+
+EPYTEST_IGNORE=(
+ testing/test_code.py
+)
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.0.4.0-fix-docs-cmd.patch
+ "${FILESDIR}"/${PN}-3.0.5-dont-repeat-standard-paths.patch
+)
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+ elog "Duplicity has many optional dependencies to support various
backends."
+ elog "Currently it's up to you to install them as necessary."
+}
