[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-nm/

[Andreas Sturmlechner]

commit:     916974366d4fe34dd6be7b90316221d15fa0cc0a
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 13 20:32:35 2026 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jan 13 20:35:56 2026 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=91697436

kde-plasma/plasma-nm: add 6.6.49.9999 stable branch

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-nm/plasma-nm-6.6.49.9999.ebuild | 81 +++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/kde-plasma/plasma-nm/plasma-nm-6.6.49.9999.ebuild 
b/kde-plasma/plasma-nm/plasma-nm-6.6.49.9999.ebuild
new file mode 100644
index 0000000000..fb30711fc4
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-6.6.49.9999.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.22.0
+QTMIN=6.10.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="6"
+KEYWORDS=""
+IUSE="openconnect teamd"
+
+COMMON_DEPEND="
+       >=app-crypt/qca-2.3.7:2[qt6(+)]
+       dev-libs/qcoro[dbus]
+       >=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+       >=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+       >=kde-frameworks/kcmutils-${KFMIN}:6
+       >=kde-frameworks/kcolorscheme-${KFMIN}:6
+       >=kde-frameworks/kcompletion-${KFMIN}:6
+       >=kde-frameworks/kconfig-${KFMIN}:6
+       >=kde-frameworks/kcoreaddons-${KFMIN}:6
+       >=kde-frameworks/kdbusaddons-${KFMIN}:6
+       >=kde-frameworks/ki18n-${KFMIN}:6
+       >=kde-frameworks/kio-${KFMIN}:6
+       >=kde-frameworks/kitemviews-${KFMIN}:6
+       >=kde-frameworks/kjobwidgets-${KFMIN}:6
+       >=kde-frameworks/knotifications-${KFMIN}:6
+       >=kde-frameworks/kservice-${KFMIN}:6
+       >=kde-frameworks/ksvg-${KFMIN}:6
+       >=kde-frameworks/kwallet-${KFMIN}:6
+       >=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+       >=kde-frameworks/kwindowsystem-${KFMIN}:6
+       >=kde-frameworks/kxmlgui-${KFMIN}:6
+       >=kde-frameworks/modemmanager-qt-${KFMIN}:6
+       >=kde-frameworks/networkmanager-qt-${KFMIN}:6[teamd=]
+       >=kde-frameworks/solid-${KFMIN}:6
+       >=kde-plasma/libplasma-${KDE_CATV}:6
+       net-misc/mobile-broadband-provider-info
+       net-misc/networkmanager[teamd=]
+       openconnect? (
+               >=dev-qt/qtwebengine-${QTMIN}:6
+               net-vpn/networkmanager-openconnect
+               net-vpn/openconnect:=
+       )
+"
+RDEPEND="${COMMON_DEPEND}
+       >=kde-frameworks/kdeclarative-${KFMIN}:6
+       >=kde-frameworks/kirigami-${KFMIN}:6
+       >=kde-frameworks/kquickcharts-${KFMIN}:6
+"
+DEPEND="${COMMON_DEPEND}
+       >=net-misc/modemmanager-1.20
+"
+BDEPEND="
+       >=kde-frameworks/kcmutils-${KFMIN}:6
+       virtual/pkgconfig
+"
+
+src_configure() {
+       local mycmakeargs=(
+               -DBUILD_OPENCONNECT=$(usex openconnect)
+       )
+
+       ecm_src_configure
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+
+       if ! has_version "kde-frameworks/kcmutils:6"; then
+               elog "${PN} is not terribly useful without 
kde-frameworks/kcmutils:6."
+               elog "However, the networkmanagement KCM can be called from 
either systemsettings"
+               elog "or manually: $ kcmshell6 kcm_networkmanagement"
+       fi
+}