[gentoo-commits] gentoo-x86 commit in net-misc/whois: ChangeLog whois-5.2.7.ebuild whois-5.2.3.ebuild whois-5.2.2.ebuild whois-5.2.0.ebuild whois-5.2.1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    15/05/07 08:08:06

  Modified:             ChangeLog
  Added:                whois-5.2.7.ebuild
  Removed:              whois-5.2.3.ebuild whois-5.2.2.ebuild
                        whois-5.2.0.ebuild whois-5.2.1.ebuild
  Log:
  Version bump. Removed old
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 
0x981CA6FC)

Revision  Changes    Path
1.215                net-misc/whois/ChangeLog

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?rev=1.215&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?rev=1.215&content-type=text/plain
diff : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?r1=1.214&r2=1.215

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v
retrieving revision 1.214
retrieving revision 1.215
diff -u -r1.214 -r1.215
--- ChangeLog   23 Apr 2015 05:15:47 -0000      1.214
+++ ChangeLog   7 May 2015 08:08:06 -0000       1.215
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/whois
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v 1.214 2015/04/23 
05:15:47 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v 1.215 2015/05/07 
08:08:06 polynomial-c Exp $
+
+*whois-5.2.7 (07 May 2015)
+
+  07 May 2015; Lars Wendler <polynomia...@gentoo.org> -whois-5.2.0.ebuild,
+  -whois-5.2.1.ebuild, -whois-5.2.2.ebuild, -whois-5.2.3.ebuild,
+  +whois-5.2.7.ebuild:
+  Version bump. Removed old.
 
   23 Apr 2015; Jeroen Roovers <j...@gentoo.org> whois-5.1.5.ebuild:
   Stable for PPC64 (bug #524264).



1.1                  net-misc/whois/whois-5.2.7.ebuild

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/whois-5.2.7.ebuild?rev=1.1&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/whois-5.2.7.ebuild?rev=1.1&content-type=text/plain

Index: whois-5.2.7.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/whois-5.2.7.ebuild,v 1.1 
2015/05/07 08:08:06 polynomial-c Exp $

EAPI=4
inherit eutils toolchain-funcs

MY_P=${P/-/_}
DESCRIPTION="improved Whois Client"
HOMEPAGE="http://www.linux.it/~md/software/";
SRC_URI="mirror://debian/pool/main/w/whois/${MY_P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc 
~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
IUSE="iconv idn nls"
RESTRICT="test" #59327

RDEPEND="iconv? ( virtual/libiconv )
        idn? ( net-dns/libidn )
        nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
        app-arch/xz-utils
        >=dev-lang/perl-5
        nls? ( sys-devel/gettext )"

src_prepare() {
        epatch "${FILESDIR}"/${PN}-4.7.2-config-file.patch

        if use nls ; then
                sed -i -e 's:#\(.*pos\):\1:' Makefile || die
        else
                sed -i -e '/ENABLE_NLS/s:define:undef:' config.h || die

                # don't generate po files when nls is disabled (bug #419889)
                sed -i -e '/^all:/s/ pos//' \
                        -e '/^install:/s/ install-pos//' Makefile || die
        fi
}

src_configure() { :;} # expected no-op

src_compile() {
        unset HAVE_ICONV HAVE_LIBIDN
        use iconv && export HAVE_ICONV=1
        use idn && export HAVE_LIBIDN=1
        tc-export CC
        emake CFLAGS="${CFLAGS} ${CPPFLAGS}"
}

src_install() {
        emake BASEDIR="${ED}" prefix=/usr install
        insinto /etc
        doins whois.conf
        dodoc README debian/changelog

        if [[ ${USERLAND} != "GNU" ]]; then
                mv "${ED}"/usr/share/man/man1/{whois,mdwhois}.1 || die
                mv "${ED}"/usr/bin/{whois,mdwhois} || die
        fi
}