commit: 71b89c742fb897a0769337058790873552cfbd79
Author: Sébastien Fabbro <bicatali <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 30 23:24:53 2016 +0000
Commit: Sebastien Fabbro <bicatali <AT> gentoo <DOT> org>
CommitDate: Wed Nov 30 23:25:12 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=71b89c74
dev-python/gammapy: version bump
Package-Manager: portage-2.3.2
dev-python/gammapy/Manifest | 1 +
dev-python/gammapy/gammapy-0.5.ebuild | 74 +++++++++++++++++++++++++++++++++++
2 files changed, 75 insertions(+)
diff --git a/dev-python/gammapy/Manifest b/dev-python/gammapy/Manifest
index e4fdd24..ee6a0c6 100644
--- a/dev-python/gammapy/Manifest
+++ b/dev-python/gammapy/Manifest
@@ -1 +1,2 @@
DIST gammapy-0.4.tar.gz 933018 SHA256
370c98b1078a19e4ac9721b807ea62a32c1f9ac323fd738b3b1d43cceccae2a3 SHA512
d44e24faddbb7064c5f222e3cb59d9d4442a128dca84bb8e8e63ac4dffe6fc3be573e4252ef2a052e2e07b51efa1151639296aa8d7785437992aab0be4986155
WHIRLPOOL
73040d13ccc1a00f6a817b01ec0c0a0a103e480ae348588410bfb578383252381cfba81abe8d0578caa2ec02d7a07699c8b0c81079ae2d1b3b33d2619c123830
+DIST gammapy-0.5.tar.gz 1054718 SHA256
7d5711b2e74b887947bde74d982a50e19723f0e2bcba1dc93836855e48112042 SHA512
24132a4ce02660724cc92c5dc8ccc8d4f096ae5ab56a27cbfead55404358885fd7eaa7fc6c95b8842d42f8492fbfa4cc2c6af66e53736576ebf3674e1ecdc69d
WHIRLPOOL
323b511379e8ffc41736ac282b583e05e408d9028269213fe33353cd109475c1355cd79909ff3015dc9d248ac7faf795f9bb62f1d159b0e04606560f80883ae4
diff --git a/dev-python/gammapy/gammapy-0.5.ebuild
b/dev-python/gammapy/gammapy-0.5.ebuild
new file mode 100644
index 00000000..55255ea
--- /dev/null
+++ b/dev-python/gammapy/gammapy-0.5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+inherit distutils-r1 eutils virtualx xdg-utils
+
+DESCRIPTION="Python package for gamma-ray astronomy"
+HOMEPAGE="https://gammapy.readthedocs.org/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+DOCS=( README.rst )
+
+RDEPEND="
+ dev-python/astropy[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/regions[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+ dev-python/astropy-helpers[${PYTHON_USEDEP}]
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+ test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+ sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+ xdg_environment_reset
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ python_setup
+ VARTEXFONTS="${T}"/fonts \
+ MPLCONFIGDIR="${BUILD_DIR}" \
+ PYTHONPATH="${BUILD_DIR}"/lib \
+ esetup.py build_sphinx --no-intersphinx
+ fi
+}
+
+python_test() {
+ virtx esetup.py test
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( docs/_build/html/. )
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "${PN} full functionality" \
+ dev-python/aplpy \
+ dev-python/astroplan \
+ dev-python/h5py \
+ dev-python/iminuit \
+ dev-python/matplotlib \
+ dev-python/naima \
+ dev-python/pandas \
+ dev-python/photutils \
+ dev-python/reproject \
+ dev-python/wcsaxes \
+ sci-libs/scipy \
+ sci-libs/scikits_image \
+ sci-libs/scikits_learn
+ # not yet in portage: sherpa, gwcs, uncertainties
+}
