commit: fefe0fdc954022b0d7edf11edd7f4c34f9c3c677
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 5 14:43:34 2019 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Mar 5 16:37:13 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fefe0fdc
dev-python/cython: Bump to 0.29.6
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/cython/Manifest | 1 +
dev-python/cython/cython-0.29.6.ebuild | 86 ++++++++++++++++++++++++++++++++++
2 files changed, 87 insertions(+)
diff --git a/dev-python/cython/Manifest b/dev-python/cython/Manifest
index 40756bdc1f9..f944f9be7c0 100644
--- a/dev-python/cython/Manifest
+++ b/dev-python/cython/Manifest
@@ -3,3 +3,4 @@ DIST Cython-0.26.1.tar.gz 1725133 BLAKE2B
b2c0433e8154ad76d921677608cae42a793326
DIST Cython-0.28.4.tar.gz 1880943 BLAKE2B
a97314147294c95fa0bd6d3fa1a1315d81f8abb46a1f2196009c1ef6f0dd7f47f81a7b31ab81d1fd00e8de37878a18a22d225055181ee74ffe4cc8105d84cd75
SHA512
67d2da2d776fc02193cfe98c8942e93905ec5e30bf4e0f9d5c965d930a034936d4c29c8248fccefff5db6d4dee054ec854994bea63fa3f64ff65df7550997c29
DIST Cython-0.29.4.tar.gz 2044382 BLAKE2B
b36d27706a3270805f66190a4cf2735eaf20b1b932365b324a433c0e58e63e860ce1500333233c3539ae697886ac0adc361a2c158d5d064a3ea05843debc3f26
SHA512
8f115e36975aaf64eda4df8b0a85378d0c80b3292dbd162be826b939def03bdc9f3eb937676e2367003c2944b570d97f50d7880becfdb2fdc5144077b4a722dc
DIST Cython-0.29.5.tar.gz 2045488 BLAKE2B
ca809728115865b7d28100943b358d8f5236382e5ae5a43d557620c3bd856407a9f52b756fc910564a6c041d64b1439d60776c90c6970614f74ee2d03f94665f
SHA512
4bbf54b248b9a08b9118d751a6bb5dbb81ae7a8238c8a3124d94bf7be67f15b68820e6ce5470903fb5d5ff5c3c213e1580f1c57a8cda33b356263f9ab46e8851
+DIST Cython-0.29.6.tar.gz 2047021 BLAKE2B
32fe6697ba407a75dad79f08fd2e33ba11b083c65f69e09cd269c8a9f445d183a8cf36794fc8b2abb5e98b9626f0c62a099367359634833f36273c7681835572
SHA512
bb8095b438a7d2567b8b831628fbb32c02299c866e41113da62fb5a5d4982dc0df947a9f723a82c52086806435d8f3518e78a803166149d476f81e042a12494e
diff --git a/dev-python/cython/cython-0.29.6.ebuild
b/dev-python/cython/cython-0.29.6.ebuild
new file mode 100644
index 00000000000..09a50cfbb74
--- /dev/null
+++ b/dev-python/cython/cython-0.29.6.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs elisp-common
+
+MY_PN="Cython"
+MY_P="${MY_PN}-${PV/_/}"
+
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="https://cython.org https://pypi.org/project/Cython/";
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh
~sparc ~x86 ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux
~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="doc emacs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ emacs? ( virtual/emacs )
+"
+DEPEND="${RDEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+ test? ( dev-python/numpy[${PYTHON_USEDEP}] )"
+
+SITEFILE=50cython-gentoo.el
+S="${WORKDIR}/${MY_PN}-${PV%_*}"
+
+python_prepare_all() {
+ # tests behavior that is illegal in Python 3.7+
+ # https://github.com/cython/cython/issues/2454
+ sed -i -e '/with_outer_raising/,/return/d' tests/run/generators_py.py
|| die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile() {
+ if ! python_is_python3; then
+ local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+ local CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+ fi
+
+ # Python gets confused when it is in sys.path before build.
+ local -x PYTHONPATH=
+
+ distutils-r1_python_compile
+}
+
+python_compile_all() {
+ use emacs && elisp-compile Tools/cython-mode.el
+
+ use doc && emake -C docs html
+}
+
+python_test() {
+ tc-export CC
+ # https://github.com/cython/cython/issues/1911
+ local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
+ "${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
+ || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
+ use doc && local HTML_DOCS=( docs/build/html/. )
+ distutils-r1_python_install_all
+
+ if use emacs; then
+ elisp-install ${PN} Tools/cython-mode.*
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
