commit: b874d10de59038a33977c32bd0ca706af86777cc
Author: Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 31 11:25:01 2019 +0000
Commit: Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Mar 31 12:12:38 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b874d10d
media-video/pitivi: Bump to 0.999 version
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>
media-video/pitivi/Manifest | 1 +
media-video/pitivi/pitivi-0.999.ebuild | 96 ++++++++++++++++++++++++++++++++++
2 files changed, 97 insertions(+)
diff --git a/media-video/pitivi/Manifest b/media-video/pitivi/Manifest
index 79e9ce92a7d..c5e225a9052 100644
--- a/media-video/pitivi/Manifest
+++ b/media-video/pitivi/Manifest
@@ -1,2 +1,3 @@
DIST pitivi-0.97.1.tar.xz 5096672 BLAKE2B
010b7ef80e0b57f83fe4e7d201a2839f65e2c8b62019d4271cd0d6d49edb44a5083024abdf13e735f94d7e681a77ef45e1d876cf6e5c20e6cc1b1876da5b3a99
SHA512
be5fcf5148349f685f0ee23a82b36d90fe0b7ff6d1d8cdcaf73272b8e5c29ddfe1d6c21353eb95f2d786fe4922a93c747403e5e27141d815f5b46f846a1d95ba
DIST pitivi-0.98.1.tar.xz 5112280 BLAKE2B
9269163a5c964a6a2b3fd094262594a38bfff4dd052ea0f3673f2ac195f197eb9b888de673e62f884137d056fba2b853d11cf7300e2f81d71c6e49402350cc40
SHA512
b6530b1b5429c4379699d7492c31ec60ddc514c94a003fe240f7e390b6349093d2f4f72abb1edb4253bd938620c73dfb361abf21915d36ff3b75332e8612bcb3
+DIST pitivi-0.999.tar.xz 12296928 BLAKE2B
16736fef4f2d16c02b64f8eba56f8c9ddb26f49742ee577da4e4c47077f8d5d71ce653dba366a041ba523153532728c5eb37cb2b76e11e9c51827efb990bd99d
SHA512
663db84a00634f0e83f0c1dd80a4f3a6603a50826905adb24fdd567c6e8bb58e20de04c7753fa04a36692cdcf5bbbcc9a87327fd3b56ebb70caffcff13835fc8
diff --git a/media-video/pitivi/pitivi-0.999.ebuild
b/media-video/pitivi/pitivi-0.999.ebuild
new file mode 100644
index 00000000000..5336afcf018
--- /dev/null
+++ b/media-video/pitivi/pitivi-0.999.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{3_5,3_6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit gnome.org meson python-single-r1 virtualx
+
+DESCRIPTION="A non-linear video editor using the GStreamer multimedia
framework"
+HOMEPAGE="http://www.pitivi.org";
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="v4l test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# XXX: recommends gst-plugins-libav and frei0r-plugins
+
+# Do not forget to check pitivi/check.py for dependencies!!!
+# pycanberra, libav, libnotify and liwnck are optional
+GST_VER="1.14.2"
+
+COMMON_DEPEND="
+ ${PYTHON_DEPS}
+ >=dev-python/pycairo-1.10[${PYTHON_USEDEP}]
+ >=x11-libs/cairo-1.10
+
+ >=media-libs/gstreamer-${GST_VER}:1.0[introspection]
+ >=media-plugins/gst-transcoder-1.8.2-r1
+"
+RDEPEND="${COMMON_DEPEND}
+ >=dev-libs/glib-2.30.0:2
+
+ >=dev-libs/gobject-introspection-1.34:=
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ >=dev-python/gst-python-1.4:1.0[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ >=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}]
+
+ gnome-base/librsvg:=
+ >=media-libs/gsound-1.0
+
+ >=media-libs/gstreamer-editing-services-${GST_VER}:1.0[introspection]
+ >=media-libs/gst-plugins-base-${GST_VER}:1.0[introspection]
+ >=media-libs/gst-plugins-bad-${GST_VER}:1.0[gtk]
+ >=media-libs/gst-plugins-good-${GST_VER}:1.0
+ >=media-plugins/gst-plugins-libav-${GST_VER}:1.0
+ >=media-plugins/gst-plugins-gdkpixbuf-${GST_VER}:1.0
+
+ >=x11-libs/libnotify-0.7[introspection]
+ x11-libs/libwnck:3[introspection]
+ >=x11-libs/gtk+-3.20.0:3[introspection]
+
+ v4l? ( >=media-plugins/gst-plugins-v4l2-${GST_VER}:1.0 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ app-text/yelp-tools
+ dev-python/setuptools
+ >=dev-util/intltool-0.35.5
+ dev-util/itstool
+ sys-devel/gettext
+ virtual/pkgconfig
+ test? ( dev-python/nose2[${PYTHON_USEDEP}] )
+"
+
+PATCHES=(
+ # Make tests optional, bug #594096
+ # https://gitlab.gnome.org/GNOME/pitivi/issues/2303
+ "${FILESDIR}"/${P}-optional-tests.patch
+)
+
+src_configure() {
+ local emesonargs=(
+ -Denable-tests=$(usex test true false)
+ )
+ meson_src_configure
+}
+
+src_compile() {
+ meson_src_compile
+}
+
+src_test() {
+ export PITIVI_TOP_LEVEL_DIR="${S}"
+ virtx meson_src_test
+}
+
+src_install() {
+ meson_src_install
+ python_fix_shebang "${D}"
+}
