commit: 7931abed5f1e0f5ab331b62cb582255b9b4fac30
Author: Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 2 14:04:38 2019 +0000
Commit: Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
CommitDate: Sun Jun 2 14:04:38 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7931abed
app-admin/system-config-printer: works with python 3.7
Package-Manager: Portage-2.3.67, Repoman-2.3.13
Signed-off-by: Alexey Shvetsov <alexxy <AT> gentoo.org>
.../system-config-printer-1.5.11-r2.ebuild | 91 ++++++++++++++++++++++
1 file changed, 91 insertions(+)
diff --git
a/app-admin/system-config-printer/system-config-printer-1.5.11-r2.ebuild
b/app-admin/system-config-printer/system-config-printer-1.5.11-r2.ebuild
new file mode 100644
index 00000000000..3138fdc7de8
--- /dev/null
+++ b/app-admin/system-config-printer/system-config-printer-1.5.11-r2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="xml"
+inherit gnome2 python-single-r1 systemd
+
+DESCRIPTION="Graphical user interface for CUPS administration"
+HOMEPAGE="https://github.com/zdohnal/system-config-printer";
+SRC_URI="https://github.com/zdohnal/${PN}/releases/download/${PV}/${P}.tar.xz
+ https://dev.gentoo.org/~asturm/distfiles/${P}-patchset-01.tar.xz";
+
+LICENSE="GPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+SLOT="0"
+
+IUSE="doc gnome-keyring policykit"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Needs cups running, bug 284005
+RESTRICT="test"
+
+# Additional unhandled dependencies
+# gnome-extra/gnome-packagekit[${PYTHON_USEDEP}] with pygobject:2 ?
+# python samba client: smbc
+# selinux: needed for troubleshooting
+COMMON_DEPEND="${PYTHON_DEPS}
+ dev-libs/glib:2
+ net-print/cups[dbus]
+ virtual/libusb:1
+ >=virtual/udev-172
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify[introspection]
+ x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+ app-text/docbook-xml-dtd:4.1.2
+ >=app-text/xmlto-0.0.22
+ dev-util/desktop-file-utils
+ dev-util/intltool
+ sys-devel/gettext
+ virtual/pkgconfig
+ doc? ( dev-python/epydoc )
+"
+RDEPEND="${COMMON_DEPEND}
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ dev-python/pycups[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/urllib3[${PYTHON_USEDEP}]
+ gnome-keyring? ( app-crypt/libsecret[introspection] )
+ policykit? ( net-print/cups-pk-helper )
+"
+
+PATCHES=(
+ "${WORKDIR}"/${P}-auth-dialog.patch
+ "${WORKDIR}"/${P}-libsecret-optional-{1,2}.patch
+ "${WORKDIR}"/${P}-scp-dbus-service-{1,2}.patch
+ "${WORKDIR}"/${P}-typo.patch
+ "${WORKDIR}"/${P}-appdata.patch
+ "${WORKDIR}"/${P}-empty-LC_MESSAGES.patch
+ "${WORKDIR}"/${P}-fdopen-utf8.patch
+ "${WORKDIR}"/${P}-typeerror.patch
+ "${WORKDIR}"/${P}-debugprint-typo.patch
+)
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_configure() {
+ gnome2_src_configure \
+ --enable-nls \
+ --with-desktop-vendor=Gentoo \
+ --with-udev-rules \
+ --with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+}
+
+src_compile() {
+ gnome2_src_compile
+ use doc && emake html
+}
+
+src_install() {
+ use doc && local HTML_DOCS=( html/. )
+ gnome2_src_install
+ python_fix_shebang "${ED}"
+}
