commit: d1c2e1a5617b801ca78c135f0f755875f4d21878
Author: Patrick McLean <patrick.mclean <AT> sony <DOT> com>
AuthorDate: Thu Nov 21 22:06:46 2019 +0000
Commit: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Thu Nov 21 23:55:11 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d1c2e1a5
dev-python/jaraco-functools: Revbump to 2.0-r1, add py38
Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>
.../jaraco-functools-2.0-r1.ebuild | 82 ++++++++++++++++++++++
1 file changed, 82 insertions(+)
diff --git a/dev-python/jaraco-functools/jaraco-functools-2.0-r1.ebuild
b/dev-python/jaraco-functools/jaraco-functools-2.0-r1.ebuild
new file mode 100644
index 00000000000..39d1e834d3d
--- /dev/null
+++ b/dev-python/jaraco-functools/jaraco-functools-2.0-r1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python{2_7,3_{5,6,7,8}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Additional functions used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.functools";
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+ >=dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]
+ dev-python/more-itertools[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep
'dev-python/backports-functools-lru-cache[${PYTHON_USEDEP}]' python2_7)
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? (
+ $(python_gen_any_dep '
+ >=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+ >=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]'
+ )
+ )
+ test? (
+ ${RDEPEND}
+ >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+ dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+ dev-python/jaraco-classes[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ )
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=( "${FILESDIR}/${P}-fix-py37-tests.patch" )
+
+python_check_deps() {
+ use doc || return 0
+
+ has_version ">=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]" && \
+ has_version ">=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]" && \
+ has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+ # avoid a setuptools_scm dependency
+ sed -i "s:use_scm_version=True:version='${PV}':" setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ cd docs || die
+ sphinx-build . _build/html || die
+ HTML_DOCS=( docs/_build/html/. )
+ fi
+}
+
+python_test() {
+ # Override pytest options to skip flake8
+ PYTHONPATH=. pytest -vv --override-ini="addopts=--doctest-modules" \
+ || die "tests failed with ${EPYTHON}"
+}
+
+#
https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
+python_install() {
+ rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+ # note: eclass may default to --skip-build in the future
+ distutils-r1_python_install --skip-build
+}
