[gentoo-commits] repo/gentoo:master commit in: dev-libs/libjcat/

[Lars Wendler]

commit:     a3d56176c09a42e9093a4bad43ade30ff1998e93
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 23 18:40:56 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Oct 23 18:56:52 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a3d56176

dev-libs/libjcat: Bump to version 0.1.4

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 dev-libs/libjcat/Manifest             |  1 +
 dev-libs/libjcat/libjcat-0.1.4.ebuild | 66 +++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/dev-libs/libjcat/Manifest b/dev-libs/libjcat/Manifest
index 34cc064bc43..97d28c25824 100644
--- a/dev-libs/libjcat/Manifest
+++ b/dev-libs/libjcat/Manifest
@@ -1 +1,2 @@
 DIST libjcat-0.1.3.tar.gz 63765 BLAKE2B 
a9847fe2a93f49773ba6451036d7908b8b615a6334557a68c94db3c402e1f502e2915bb1abc9f58c495fe1453cb5653cae9b548d2f9d7b39dcd5d7824e965bc2
 SHA512 
f021e10d740ac6d0f0c73cefc9deacdbc74882a5e340b249c28427ece4917358940413914ce19c5aac96c86d8056349ff2ee633c2a9541f4382f109d9e0d9e69
+DIST libjcat-0.1.4.tar.gz 63900 BLAKE2B 
509a9916aa77193835e5a29a152acb0eb1cee24b6aae3e256dee42c1fd598b9c181009cdea4c276cc0d8c8cb56d22b9073f44dd11b7fab59d29df3633af6d042
 SHA512 
d58860410ce6e9d35a1eefcd0c6fcd956db42a12a3e8f856e19e3abe8bd6ae304ab7a60e2c1ee28f3848f2fee3b406dd900d7c1024eca5602797711528d3f7e3

diff --git a/dev-libs/libjcat/libjcat-0.1.4.ebuild 
b/dev-libs/libjcat/libjcat-0.1.4.ebuild
new file mode 100644
index 00000000000..141c38f2a5f
--- /dev/null
+++ b/dev-libs/libjcat/libjcat-0.1.4.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE="xml"
+
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files "
+HOMEPAGE="https://github.com/hughsie/libjcat";
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gpg gtk-doc +introspection +man pkcs7 test vala"
+
+RDEPEND="dev-libs/glib:2
+       dev-libs/json-glib:=
+       gpg? (
+               app-crypt/gpgme
+               dev-libs/libgpg-error
+       )
+       introspection? ( dev-libs/gobject-introspection:= )
+       pkcs7? ( net-libs/gnutls )
+       vala? ( dev-lang/vala:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+       $(python_gen_any_dep '
+               dev-python/setuptools[${PYTHON_USEDEP}]
+       ')
+       gtk-doc? ( dev-util/gtk-doc )
+       man? ( sys-apps/help2man )
+       test? ( net-libs/gnutls[tools] )"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-0.1.1-disable_installed_tests.patch
+       "${FILESDIR}"/${PN}-0.1.3-optional_vala.patch
+)
+
+python_check_deps() {
+       has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+       xdg_environment_reset
+       use vala && vala_src_prepare
+       default
+}
+
+src_configure() {
+       local emesonargs=(
+               $(meson_use gtk-doc gtkdoc)
+               $(meson_use gpg)
+               $(meson_use introspection)
+               $(meson_use man)
+               $(meson_use pkcs7)
+               $(meson_use test tests)
+               $(meson_use vala vala-bindings)
+       )
+       meson_src_configure
+}