[gentoo-commits] repo/gentoo:master commit in: dev-util/debugedit/

[Michał Górny]

commit:     b849314e07039ca77368c2f8209540988f1a064f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 11 07:11:02 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Dec 11 07:11:02 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b849314e

dev-util/debugedit: Bump to 4.16.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/debugedit/Manifest                |  1 +
 dev-util/debugedit/debugedit-4.16.1.ebuild | 91 ++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/dev-util/debugedit/Manifest b/dev-util/debugedit/Manifest
index f75fa034aa9..b462aca4af1 100644
--- a/dev-util/debugedit/Manifest
+++ b/dev-util/debugedit/Manifest
@@ -1 +1,2 @@
 DIST rpm-4.16.0.tar.bz2 4341683 BLAKE2B 
5161e5dcc6d9a1f1d4b8e44740fb368050b808fd9e8b8276fb17b530a4642e1b9ad104b5a30c0071215aef7f823eeab10988dd41f73af1c52d575529c374b5eb
 SHA512 
177119c3ac3d48980db55bb4ba0fdbb2a911968e5efc690bfa8cc343f850fc90531cc0dee6dd8e45d2b14f0d951ced35bd8893d24011b7f270745d281ddf4e3d
+DIST rpm-4.16.1.tar.bz2 4348973 BLAKE2B 
5f415099ed5b4f3425c1cbd02476c3066ef51e8efbe09829c0c7d9732cfdeed76ab0c5eed113a1b007d35bf5d5fb1c60543b7ef23319ba0f63550d598e98dcdd
 SHA512 
cbce8381e7a0bdaf2c7529d0ac91fda15e663db7a76b02652d53327ebcd7d5b6b6154d5e88feeda87f71727a036e7a2afcd57c7dcddef610e32957b9e430d367

diff --git a/dev-util/debugedit/debugedit-4.16.1.ebuild 
b/dev-util/debugedit/debugedit-4.16.1.ebuild
new file mode 100644
index 00000000000..d2c33879440
--- /dev/null
+++ b/dev-util/debugedit/debugedit-4.16.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+MY_P=rpm-${PV}
+DESCRIPTION="Stand-alone debugedit from RPM"
+HOMEPAGE="https://rpm.org
+       https://github.com/rpm-software-management/rpm";
+SRC_URI="http://ftp.rpm.org/releases/rpm-$(ver_cut 1-2).x/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+       sys-libs/zlib:=
+       >=dev-libs/popt-1.7
+       >=dev-libs/elfutils-0.176-r1
+       dev-libs/nss
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+       eapply_user
+
+       # cheat it into believing we're bundling db
+       mkdir -p db/dist || die
+       touch db/dist/configure || die
+       chmod +x db/dist/configure || die
+       echo 'install:' > db3/Makefile || die
+
+       # TODO: why do we need to do this?
+       mkdir rpm || die
+       find -name '*.h' -exec cp {} rpm/ ';' || die
+}
+
+src_configure() {
+       append-cppflags -I"${EPREFIX}/usr/include/nss" 
-I"${EPREFIX}/usr/include/nspr"
+       local myconf=(
+               # force linking to static librpmio
+               --disable-shared
+
+               # disable linking compression libraries
+               ac_cv_header_bzlib_h=no
+               ac_cv_header_lzma_h=no
+               --disable-zstd
+
+               # fake some libraries we don't use
+               ac_cv_header_magic_h=yes
+               ac_cv_lib_magic_magic_open=yes
+
+               # use nss as crypto provider
+               --with-crypto=nss
+
+               # disable other stuff irrelevant to debugedit
+               --disable-bdb
+               --disable-nls
+               --disable-plugins
+               --disable-python
+               --without-acl
+               --without-archive
+               --without-cap
+               --without-external-db
+               --without-hackingdocs
+               --without-lua
+               --without-selinux
+       )
+       econf "${myconf[@]}"
+}
+
+src_compile() {
+       emake -C misc
+       emake -C rpmio
+       emake debugedit
+}
+
+src_test() {
+       :
+}
+
+src_install() {
+       dobin debugedit
+}