commit: 5e1cd675290b5987631bfd1e2d28e418fcf0fc0f
Author: Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 23 20:13:27 2021 +0000
Commit: Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
CommitDate: Sat Jan 23 20:13:27 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e1cd675
games-roguelike/stone-soup: remove old
Signed-off-by: Erik Mackdanz <stasibear <AT> gentoo.org>
Package-Manager: Portage-3.0.12, Repoman-3.0.2
.../stone-soup/stone-soup-0.25.1-r1.ebuild | 171 ---------------------
1 file changed, 171 deletions(-)
diff --git a/games-roguelike/stone-soup/stone-soup-0.25.1-r1.ebuild
b/games-roguelike/stone-soup/stone-soup-0.25.1-r1.ebuild
deleted file mode 100644
index 0c8a1930f33..00000000000
--- a/games-roguelike/stone-soup/stone-soup-0.25.1-r1.ebuild
+++ /dev/null
@@ -1,171 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# TODO
-# - attempt +test, linked bug claims to be fixed
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6,7,8,9} )
-VIRTUALX_REQUIRED="manual"
-inherit desktop python-any-r1 eutils xdg-utils toolchain-funcs
-
-MY_P="stone_soup-${PV}"
-DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting
in dungeons"
-HOMEPAGE="https://crawl.develz.org";
-SRC_URI="
-
https://github.com/crawl/crawl/releases/download/${PV}/${PN/-/_}-${PV}.zip
- https://dev.gentoo.org/~hasufell/distfiles/${PN}.png
- https://dev.gentoo.org/~hasufell/distfiles/${PN}.svg
-"
-
-# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
-# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
-# Public Domain|CC0: most of tiles
-# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
-LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="debug ncurses sound test +tiles"
-# test is broken
-# see https://crawl.develz.org/mantis/view.php?id=6121
-RESTRICT="test"
-
-RDEPEND="
- dev-db/sqlite:3
- =dev-lang/lua-5.1*:0=
- sys-libs/zlib
- !ncurses? ( !tiles? ( sys-libs/ncurses:0 ) )
- ncurses? ( sys-libs/ncurses:0 )
- tiles? (
- media-fonts/dejavu
- media-libs/freetype:2
- media-libs/libpng:0
- sound? (
- media-libs/libsdl2[X,opengl,sound,video]
- media-libs/sdl2-mixer
- )
- !sound? ( media-libs/libsdl2[X,opengl,video] )
- media-libs/sdl2-image[png]
- virtual/glu
- virtual/opengl
- )"
-DEPEND="${RDEPEND}
- app-arch/unzip
- dev-lang/perl
- ${PYTHON_DEPS}
- $(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
- sys-devel/flex
- tiles? (
- app-arch/advancecomp
- media-gfx/pngcrush
- sys-libs/ncurses:0
- )
- virtual/pkgconfig
- virtual/yacc
- "
-
-S=${WORKDIR}/${MY_P}/source
-S_TEST=${WORKDIR}/${MY_P}_test/source
-PATCHES=(
- "${FILESDIR}"/fixed-font-path.patch
- "${FILESDIR}"/gitless-1.patch
- "${FILESDIR}"/rltiles-ldflags-libs.patch
-)
-
-python_check_deps() {
- has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-
- python-any-r1_pkg_setup
-
- if use !ncurses && use !tiles ; then
- ewarn "Neither ncurses nor tiles frontend"
- ewarn "selected, choosing ncurses only."
- ewarn "Note that you can also enable both."
- fi
-
- if use sound && use !tiles ; then
- ewarn "Sound support is only available with tiles."
- fi
-}
-
-src_prepare() {
- default
- python_fix_shebang "${S}/util/species-gen.py"
-}
-
-src_compile() {
-
- # Insurance that we're not using bundled lib sources
- rm -rf contrib || die "Couldn't delete contrib directory"
-
- export HOSTCXX=$(tc-getBUILD_CXX)
-
- # leave DATADIR at the top
- myemakeargs=(
- $(usex debug "FULLDEBUG=y DEBUG=y" "")
- BUILD_LUA=
- AR="$(tc-getAR)"
- CFOPTIMIZE=''
- CFOTHERS="${CXXFLAGS}"
- CONTRIBS=
- DATADIR="/usr/share/${PN}"
- GCC="$(tc-getCC)"
- GXX="$(tc-getCXX)"
- LDFLAGS="${LDFLAGS}"
- MAKEOPTS="${MAKEOPTS}"
- PKGCONFIG="$(tc-getPKG_CONFIG)"
- RANLIB="$(tc-getRANLIB)"
- SAVEDIR="~/.crawl"
- SOUND=$(usex sound "y" "")
- STRIP=touch
- USE_LUAJIT=
- V=1
- prefix="/usr"
- )
-
- if use ncurses || (use !ncurses && use !tiles) ; then
- emake "${myemakeargs[@]}"
- # move it in case we build both variants
- use tiles && { mv crawl "${WORKDIR}"/crawl-ncurses || die ;}
- fi
-
- if use tiles ; then
- emake clean
- emake "${myemakeargs[@]}" "TILES=y"
- fi
-}
-
-src_install() {
- emake "${myemakeargs[@]}" $(usex tiles "TILES=y" "") DESTDIR="${D}"
prefix_fp="" bin_prefix="${D}/usr/bin" install
- [[ -e "${WORKDIR}"/crawl-ncurses ]] && dobin "${WORKDIR}"/crawl-ncurses
-
- # don't relocate docs, needed at runtime
- rm -rf "${D}/usr/share/${PN}"/docs/license
-
- doman "${WORKDIR}/${MY_P}"/docs/crawl.6
-
- # icons and menu for graphical build
- if use tiles ; then
- doicon -s 48 "${DISTDIR}"/${PN}.png
- doicon -s scalable "${DISTDIR}"/${PN}.svg
- make_desktop_entry crawl
- fi
-}
-
-pkg_postinst() {
- xdg_icon_cache_update
-
- if use tiles && use ncurses ; then
- elog "Since you have enabled both tiles and ncurses frontends"
- elog "the ncurses binary is called 'crawl-ncurses' and the"
- elog "tiles binary is called 'crawl'."
- fi
-}
-
-pkg_postrm() {
- xdg_icon_cache_update
-}
