[gentoo-commits] repo/gentoo:master commit in: dev-util/include-what-you-use/

[Florian Schmaus]

commit:     06e036ef8f04afe4eac842b7fae63204fe68b47b
Author:     Florian Schmaus <flow <AT> gentoo <DOT> org>
AuthorDate: Mon Dec  6 08:31:56 2021 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Mon Dec  6 08:32:15 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=06e036ef

dev-util/include-what-you-use: add 0.17

Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 dev-util/include-what-you-use/Manifest             |  1 +
 .../include-what-you-use-0.17.ebuild               | 57 ++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/dev-util/include-what-you-use/Manifest 
b/dev-util/include-what-you-use/Manifest
index e569aeb6e6bd..c5487da81efb 100644
--- a/dev-util/include-what-you-use/Manifest
+++ b/dev-util/include-what-you-use/Manifest
@@ -1 +1,2 @@
 DIST include-what-you-use-0.16.tar.gz 742573 BLAKE2B 
b8cd90db490d13f140126df8955d0968a9248480da09ca29b82fe1178c779ca75e6f29239bc6fb1556200c7d7c498f2340839e8500455ecaed9e6199fd3d55f7
 SHA512 
2923e18c40ddc5c03458b896d991adde03d489c6645ecc3cc4f69a508e323534afdef3233943e99533ffc21c64a10a8a5c635dc4797a61edf09d0a7a918a3cd5
+DIST include-what-you-use-0.17.tar.gz 747385 BLAKE2B 
0f584521b070eec6448d65d6dc4c4fe09110e85099d2696da82be800ee82522185f378c849559d899424a85864878d5b7b4790b900c438ef1f008262d6de6e28
 SHA512 
2439e3dd37163d3953fc1e45614fb4325be093a162f25d0f45fa8126b2313942a7c8d45ed12454dfbfeb4cb4fcf2f4e3eebdc0ec5da14dad23533f7a0bf58290

diff --git a/dev-util/include-what-you-use/include-what-you-use-0.17.ebuild 
b/dev-util/include-what-you-use/include-what-you-use-0.17.ebuild
new file mode 100644
index 000000000000..ab4c265670d8
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-0.17.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit cmake llvm python-single-r1
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/";
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LLVM_MAX_SLOT=13
+
+RDEPEND="
+       sys-devel/clang:${LLVM_MAX_SLOT}=
+       ${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+llvm_check_deps() {
+       has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+       llvm_pkg_setup
+       python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       cmake_src_prepare
+       python_fix_shebang .
+}
+
+src_configure() {
+       local mycmakeargs=(
+               # Note [llvm install path]
+               # Unfortunately all binaries using clang driver
+               # have to reside at the same path depth as
+               # 'clang' binary itself. See bug #625972
+               # Thus as a hack we install it to the same directory
+               # as llvm/clang itself.
+               -DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
+       )
+       cmake_src_configure
+}
+
+src_test() {
+       "${EPYTHON}" run_iwyu_tests.py
+}