[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgusb/

[Matt Turner]

commit:     292e51945e394bc65510a43748d0b55175f929b9
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 18 03:39:50 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Dec 18 03:47:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=292e5194

dev-libs/libgusb: Version bump to 0.3.9

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libgusb/Manifest             |  1 +
 dev-libs/libgusb/libgusb-0.3.9.ebuild | 63 +++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-libs/libgusb/Manifest b/dev-libs/libgusb/Manifest
index 79ecf5093f89..540af78296f8 100644
--- a/dev-libs/libgusb/Manifest
+++ b/dev-libs/libgusb/Manifest
@@ -1 +1,2 @@
 DIST libgusb-0.3.7.tar.xz 41844 BLAKE2B 
e0829430a7c4c9372ebc061ca8245ecd6b30f0922e4e37ae41f7f65055e7339b5a3a882c5526ea5e5663be3b7c1ad71fee7da5cffb501d63bd1cda2b618fd40d
 SHA512 
65a35be62bff689621f418abf045f62f946c67488dd021d363ab252b9b3a2380898ec763b374f7da50901945eda666fdcae7cbfda7e143544175d7ade3ebc20d
+DIST libgusb-0.3.9.tar.xz 42708 BLAKE2B 
6d73f3dba891dc7594c2df02198bb1632c8e7ccea2b60f5071c87ae1111b6e2cfed4f9b912f58f788f199c5ee075db156a4d7326aa9b5e6448581c2acd1af469
 SHA512 
4a4545d9e8ccadf2c66ef891936a30b2b73b7b471a9b0e945da21fd2b55efc3a8d12cfd5127dfcbca0ba24f565b25f8edd7a276b70a6615eb4b2201791745c6c

diff --git a/dev-libs/libgusb/libgusb-0.3.9.ebuild 
b/dev-libs/libgusb/libgusb-0.3.9.ebuild
new file mode 100644
index 000000000000..2df3883b3301
--- /dev/null
+++ b/dev-libs/libgusb/libgusb-0.3.9.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb";
+SRC_URI="https://people.freedesktop.org/~hughsient/releases/${P}.tar.xz";
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv 
~sparc ~x86"
+
+IUSE="gtk-doc +introspection static-libs test +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+       >=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
+       virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+       introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+       sys-apps/hwdata
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       $(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+       gtk-doc? (
+               app-text/docbook-xml-dtd:4.1.2
+               app-text/docbook-xml-dtd:4.4
+               dev-util/gtk-doc
+       )
+       vala? ( $(vala_depend) )
+       virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+       has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+       use vala && vala_src_prepare
+       default
+}
+
+multilib_src_configure() {
+       local emesonargs=(
+               -Ddefault_library=$(usex static-libs both shared)
+               $(meson_use test tests)
+               $(meson_native_use_bool vala vapi)
+               -Dusb_ids="${EPREFIX}"/usr/share/hwdata/usb.ids
+               $(meson_native_use_bool gtk-doc docs)
+               $(meson_native_use_bool introspection)
+
+       )
+       meson_src_configure
+}