commit: 88351eaf28766d225d1fb505471fae3553cd9813
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 22 16:31:37 2021 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Dec 22 18:09:46 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=88351eaf
dev-python/django-redis: add 5.2.0
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/django-redis/Manifest | 1 +
dev-python/django-redis/django-redis-5.2.0.ebuild | 79 +++++++++++++++++++++++
2 files changed, 80 insertions(+)
diff --git a/dev-python/django-redis/Manifest b/dev-python/django-redis/Manifest
index b1ea183a858b..cec28dee6521 100644
--- a/dev-python/django-redis/Manifest
+++ b/dev-python/django-redis/Manifest
@@ -1,2 +1,3 @@
DIST django-redis-5.0.0.tar.gz 47508 BLAKE2B
67d87bcbde16730abd71945fe081d425c1047962ff2ca0c382f65d0588ef72103204f8febfeeda9ea382cf53a5c871c087a85ea817f04fac383961f69324557f
SHA512
4516e30122845b49789f04fd079b5bc99a732e814d82deb817f14d105895069defa627f1852ce3fd8464de313a5f01ba81f87272f7a98830f7100dbb0c0bfb12
DIST django-redis-5.1.0.tar.gz 44112 BLAKE2B
9b3b142b1817f4c206754ab42b4fc63dca33ac40013eca9fdbf5c797d4c55a745bfb290835904967443729f12dc0d07e0a0c89f81c7afa6173b2687fb72c4246
SHA512
eb552eafd2cedc7c550ce6ad1fc56af163a65795c05748a0fc0dc0642092910bbf5163a5ef27bd6c4a4e4bef159c9fb6ce4fb78e64c1964762b8a1330e23e9f7
+DIST django-redis-5.2.0.tar.gz 44132 BLAKE2B
5d9680e43bfff506924b90cdce4fcbf40883a732af6b599c2e36d8549ce2aedbd69540b187152dc8fdc0d2a93b21c5fd2724d6386772f9b4af8632e38414b577
SHA512
65d3dc6b1d72c8b90908cf368cb66ac2eb74bdd32d0b42c8a5288b4448bd7444b21320251262627bc950eaf0d1a1ef0c3014761b690122bea9e5e20f744dd433
diff --git a/dev-python/django-redis/django-redis-5.2.0.ebuild
b/dev-python/django-redis/django-redis-5.2.0.ebuild
new file mode 100644
index 000000000000..cf93adbb66fe
--- /dev/null
+++ b/dev-python/django-redis/django-redis-5.2.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Full featured redis cache backend for Django"
+HOMEPAGE="https://github.com/jazzband/django-redis/";
+SRC_URI="mirror://pypi/${PN:0:1}"/${PN}/${P}.tar.gz
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=dev-python/django-2.2[${PYTHON_USEDEP}]
+ >=dev-python/redis-py-3.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-db/redis
+ dev-python/lz4[${PYTHON_USEDEP}]
+ dev-python/msgpack[${PYTHON_USEDEP}]
+ dev-python/pytest-django[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ sed -e '/--cov/d' \
+ -e '/--no-cov/d' \
+ -e '/redis/s:,<4::' \
+ -i setup.cfg || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ cd tests || die
+ local setting_file settings=(
+ settings.sqlite
+ settings.sqlite_json
+ settings.sqlite_lz4
+ settings.sqlite_msgpack
+ settings.sqlite_sharding
+ settings.sqlite_zlib
+ # TODO: requires pyzstd
+# settings.sqlite_zstd
+ )
+ for setting_file in "${settings[@]}"; do
+ einfo "Testing ${setting_file} configuration"
+ epytest "--ds=${setting_file}"
+ done
+}
+
+src_test() {
+ local redis_pid="${T}"/redis.pid
+ local redis_port=6379
+ local redis_test_config="
+ daemonize yes
+ pidfile ${redis_pid}
+ port ${redis_port}
+ bind 127.0.0.1
+ "
+
+ # Spawn Redis itself for testing purposes
+ einfo "Spawning Redis"
+ einfo "NOTE: Port ${redis_port} must be free"
+ "${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+ # Run the tests
+ distutils-r1_src_test
+
+ # Clean up afterwards
+ kill "$(<"${redis_pid}")" || die
+}
