[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-firewall/

[Andreas Sturmlechner]

commit:     56d954164fbe3350bf4d55db361847014ba8f4cc
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jan  4 12:05:51 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jan  4 15:09:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=56d95416

kde-plasma/plasma-firewall: 5.23.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.23.5.ebuild  | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/kde-plasma/plasma-firewall/Manifest 
b/kde-plasma/plasma-firewall/Manifest
index a58e3e8862f4..1f7557e90f15 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1 +1,2 @@
 DIST plasma-firewall-5.23.4.tar.xz 344036 BLAKE2B 
f4ba093bb21680f76bbb7040b6bdb25c122d38574b1e117fb9966b860d8d68ca19725f2c8656bf187afdea609c1e302b03b876bb4f02d2fe3c8383eb5b626f35
 SHA512 
2628ce262138e5f7526556d788169e32bb143ca4f63b6dc2fee222ec1772835a6d311e24eb01de73c2fdff52319b74c857990acfe3e960f7025d2c05a3baeac5
+DIST plasma-firewall-5.23.5.tar.xz 344132 BLAKE2B 
3277329f223f5b4afe33bcf663b8c9f999a8dda4cab593e04d57fb8b2d6d4d899f76f803ca6cc8e3ef718bbcb09f2cb6d24dbaa1c3abcbfa5e163dd791f066ca
 SHA512 
c18b25ad85f57da80edfc03cd445d317162ad2f952fe7ecd09f43af274798acd965de0f8643a636bee74e3572f0ab66f3db876126009b9c98f486a1cfe0e386e

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.23.5.ebuild 
b/kde-plasma/plasma-firewall/plasma-firewall-5.23.5.ebuild
new file mode 100644
index 000000000000..5b21913225e9
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.23.5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.86.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall";
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+       >=dev-qt/qtdbus-${QTMIN}:5
+       >=dev-qt/qtdeclarative-${QTMIN}:5
+       >=dev-qt/qtgui-${QTMIN}:5
+       >=dev-qt/qtnetwork-${QTMIN}:5
+       >=dev-qt/qtx11extras-${QTMIN}:5
+       >=dev-qt/qtxml-${QTMIN}:5
+       >=kde-frameworks/kauth-${KFMIN}:5
+       >=kde-frameworks/kcmutils-${KFMIN}:5
+       >=kde-frameworks/kconfig-${KFMIN}:5
+       >=kde-frameworks/kcoreaddons-${KFMIN}:5
+       >=kde-frameworks/kdeclarative-${KFMIN}:5
+       >=kde-frameworks/ki18n-${KFMIN}:5
+       >=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+       ${PYTHON_DEPS}
+       firewalld? ( net-firewall/firewalld )
+       ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+       ecm_src_prepare
+       # this kind of cmake magic doesn't work for us at all.
+       sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+               -i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+               -DBUILD_UFW_BACKEND=$(usex ufw)
+       )
+       ecm_src_configure
+}
+
+pkg_postinst () {
+       ecm_pkg_postinst
+
+       if ! has_version sys-apps/systemd; then
+               ewarn "${PN} is not functional without sys-apps/systemd at this 
point."
+               ewarn "See also: https://bugs.gentoo.org/778527";
+       fi
+}