commit: 12b82e77a5b1bc6f096ea5288bd7eb6bfc6da725
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 7 18:08:07 2022 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 7 18:09:29 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=12b82e77
dev-python/mypy: add 0.931
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/mypy/Manifest | 1 +
dev-python/mypy/mypy-0.931.ebuild | 64 +++++++++++++++++++++++++++++++++++++++
2 files changed, 65 insertions(+)
diff --git a/dev-python/mypy/Manifest b/dev-python/mypy/Manifest
index 2dfd0efa3b08..7dc76090bcc0 100644
--- a/dev-python/mypy/Manifest
+++ b/dev-python/mypy/Manifest
@@ -1,3 +1,4 @@
DIST mypy-0.910.tar.gz 2551057 BLAKE2B
a3c6939c8f0e2ea19a3a3f91031330df2fb25a93cc3f9239535f15c17eedcca5716cc75c5412a1d345d8572d396c3d7128e38989fd694833cb6aec8366ac4afe
SHA512
49060c13da8bf17385b6b1db6efa9ac5771f2bac92d26760c4087cf128de22846b8a062f38e83ecff524e7893f8c9cd0647a2ef89e10387138544436a2840459
DIST mypy-0.921.tar.gz 2730985 BLAKE2B
cfb7b54165b961758891fcf225f1a7d6bd9c6a7b14e6bb6d8adb990ed047bc4983b5e82de6709d3b8db85a3914e1bae2be4fd36e878d37db7387ebe6e81daac1
SHA512
f592d440b45a1bbcab973aeb717ffc805164168f1369793067a46bd2884fedcb9f981bfadd3447c6801120042553a7a7110d8cfc4e1649241d3b8685dffef653
DIST mypy-0.930.tar.gz 2777310 BLAKE2B
4681991993b04679d21c8f6bf8327a02eb628addc289ed22fbf06e4865ee9e60b90ab41a0d0b069d0a50924bf210816bdb87cff902d4424741f4e141f0957684
SHA512
f7f7ed762eb0f56b46a174c51c34423633d72b5046129617e456c41647705380b014c0c27bd0a104319e4872f2a7d7900a260bf6151d4419c95c93e4c01c6e9d
+DIST mypy-0.931.tar.gz 2779826 BLAKE2B
11986102c6bc498a23bae52002e6ac515fa03724eed867b5356e3fb9aaa9a6eb7e699b612ab81b99dac215119402beecc702421fa82d655913976889dd4cb833
SHA512
8a336ae2f784c8ff912fc6b7dd53ed106cf14f435cee65604de74b8d4d7ab39ad65af0646060ef78e958d5a51a1de090fad628461412f2eef9593a8c032aa87a
diff --git a/dev-python/mypy/mypy-0.931.ebuild
b/dev-python/mypy/mypy-0.931.ebuild
new file mode 100644
index 000000000000..6b38a61e74be
--- /dev/null
+++ b/dev-python/mypy/mypy-0.931.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Optional static typing for Python"
+HOMEPAGE="http://www.mypy-lang.org/";
+SRC_URI="https://github.com/python/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390
~sparc ~x86"
+
+# stubgen collides with this package: https://bugs.gentoo.org/585594
+RDEPEND="
+ !dev-util/stubgen
+ >=dev-python/psutil-4[${PYTHON_USEDEP}]
+ >=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+ <dev-python/typed-ast-1.5.0[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-3.7.4[${PYTHON_USEDEP}]
+ >=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+ <dev-python/mypy_extensions-0.5.0[${PYTHON_USEDEP}]
+ dev-python/tomli[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ >=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+ >=dev-python/lxml-4.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-6.1.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-1.18[${PYTHON_USEDEP}]
+ >=dev-python/py-1.5.2[${PYTHON_USEDEP}]
+ >=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+# this requires packaging a lot of type stubs
+export MYPY_USE_MYPYC=0
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Fails with pytest-xdist 2.3.0
+ # https://github.com/python/mypy/issues/11019
+ mypy/test/teststubtest.py
+ # fails due to setuptools deprecation warnings
+ mypyc/test/test_run.py::TestRun::run-imports.test::testImports
+ )
+
+ [[ "${EPYTHON}" == "python3.10" ]] && EPYTEST_DESELECT+=(
+ # https://github.com/python/mypy/issues/11018
+ mypyc/test/test_commandline.py::TestCommandLine::testErrorOutput
+ )
+
+ # Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
+ # fail with high COLUMNS values
+ local -x COLUMNS=80
+ epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
