commit: dc7c36f403d81a9b7199c85a96746d068796f342
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 10 12:44:34 2022 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Jun 10 13:28:03 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dc7c36f4
net-wireless/gnome-bluetooth: Version bump to 42.1
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
net-wireless/gnome-bluetooth/Manifest | 1 +
.../gnome-bluetooth/gnome-bluetooth-42.1.ebuild | 69 ++++++++++++++++++++++
2 files changed, 70 insertions(+)
diff --git a/net-wireless/gnome-bluetooth/Manifest
b/net-wireless/gnome-bluetooth/Manifest
index f53082d2d5a5..650ab870c1af 100644
--- a/net-wireless/gnome-bluetooth/Manifest
+++ b/net-wireless/gnome-bluetooth/Manifest
@@ -1,2 +1,3 @@
DIST gnome-bluetooth-3.34.5.tar.xz 353936 BLAKE2B
40300752830f71d436591e22a64a282745d8419ee46de534f76c4871a86a4c8f7b2203e3ddc4ca08d26348b97bf4a68315802ffa09c69265c55001e4806c7f1e
SHA512
48431b3d19083705a6623442c5cd2d6c14962cdf30fc599ba47dceb6612b80142af77e1b6df142b530cb1015638081a06de38a3034177e0d05a354c40f19d9e5
DIST gnome-bluetooth-42.0.tar.xz 302440 BLAKE2B
f7e02efe04b1dddee365b9c316368d92428099d6d1191d9c785018bc4bebc19942e7216bd7e6e824cd132a53b6750b1f41393d270e99718312c96da7f6a4ad5b
SHA512
769bd9300fa1d830240e84257230425fe7f2e871cbd6c8fa6416514487a26326601a21c16075a66cf886850bab17f5c8e2235463f3695ea194c9230d6e50337c
+DIST gnome-bluetooth-42.1.tar.xz 302148 BLAKE2B
480456f3944ffdc4a6a10b099f4e2ec04b8e0c916dbe1e595733e45b0b781fa22852646d1e6def69cc86efa66020fa2d845027d6f7e2f137c10478cfd9b6af5a
SHA512
05fc7076e707c447cd786fbaf8536c754b00972c450f8743dcd79f73f747e16eb0c9321dafc1deeef8d2bdcbfcbcbbf15156543d7b3bc696cb34d57ce5bb24fb
diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-42.1.ebuild
b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.1.ebuild
new file mode 100644
index 000000000000..5e6406f5bbce
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+inherit gnome.org meson python-any-r1 xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeBluetooth";
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="3/13" # subslot = libgnome-bluetooth-3 soname version
+IUSE="gtk-doc +introspection sendto test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+DEPEND="
+ >=dev-libs/glib-2.44:2
+ >=gui-libs/gtk-4.4:4[introspection?]
+ media-libs/gsound
+ >=gui-libs/libadwaita-1.1:1
+ >=x11-libs/libnotify-0.7.0
+ virtual/libudev
+ >=sys-power/upower-0.99.14
+ introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+ acct-group/plugdev
+ virtual/udev
+ >=net-wireless/bluez-5
+ sendto? ( !net-wireless/gnome-bluetooth:2 )
+"
+BDEPEND="
+ dev-libs/libxml2:2
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+ virtual/pkgconfig
+ test? (
+ $(python_gen_any_dep '
+ >=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ ')
+ )
+"
+
+python_check_deps() {
+ if use test; then
+ has_version -b "dev-python/python-dbusmock[${PYTHON_USEDEP}]" &&
+ has_version -b "dev-python/dbus-python[${PYTHON_USEDEP}]"
+ fi
+}
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use sendto)
+ $(meson_use gtk-doc gtk_doc)
+ $(meson_use introspection)
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+}
