commit: ea6abd54df7c609c36b77007ccc906180c266866
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 12 04:16:07 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jun 12 05:41:11 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ea6abd54
dev-python/setuptools: Bump to 62.3.4
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/setuptools/Manifest | 1 +
dev-python/setuptools/setuptools-62.3.4.ebuild | 133 +++++++++++++++++++++++++
2 files changed, 134 insertions(+)
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 00e8bc3f687b..c7dee0fa339c 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -4,3 +4,4 @@ DIST setuptools-62.2.0.tar.gz 2512927 BLAKE2B
34932917fb635aa434b574d2e47d1dd0dd
DIST setuptools-62.3.1.tar.gz 2583892 BLAKE2B
ad6afbe6b879b4ffd3dc576c3b1746d989b0ad2cdb2527873b2b55e9d30d3dff52cff4ac25824e3dd1f04ba53eeb5c6786845097fe408981ecb009d0cc52082d
SHA512
7f24e57951638d8cab1c1efa4fbe482179c26ebcfb3276e22896f0b0878753103b4527e804312483d71f44a2b2e62a6bdbf2f8de2d9d1384c025a51a2878ae71
DIST setuptools-62.3.2.tar.gz 2583924 BLAKE2B
54229ba7505d162b379c77121d4974b31feecdd44346688b0bdedf0d63010cc7330001a862e51a86f7c560d0518e32c62ad5daa4be2a84dcd87180fc16fff193
SHA512
8674ff31b04f9229b28247f6035aff3d6b3be6f0a197c7059bd55d9dd390d6cec067ac59def830c3f98dde7fefec72a65cbec34ae923b5088d4b491fea8828ac
DIST setuptools-62.3.3.tar.gz 2586270 BLAKE2B
764f90a5b2585f05b6ae0ad23568a08069bb4ca776c969635dfaceb6b3f64dc6d56291c3e9f0a4540f0416eab9122f5d7d6ad193a5f604949b5827f3cfc2d1a9
SHA512
a7ca81b3f7adedb15a4ff3607654d1a4615de1b30a22aa5cbe4b0a8077db8bdd9348167cbb6deb97e1076d320c2a2a4b0d30acda389905d6503786902eeb66af
+DIST setuptools-62.3.4.tar.gz 2590435 BLAKE2B
089bb185b65107d54b3a17b423caa28b0505566f8e19efaf34ac347e074492278699295b5e8856756312182a78d524ae5098e86783c5c6e089bdbe2de1d1f60d
SHA512
edd9595971ee3cca2d1280e695401d8e4aa38796af89f24132d81b897004147ff4f4fc8daebf6fef0606512cc71e09487a2cb416deeecd851a82abed30f57887
diff --git a/dev-python/setuptools/setuptools-62.3.4.ebuild
b/dev-python/setuptools/setuptools-62.3.4.ebuild
new file mode 100644
index 000000000000..66341af9f120
--- /dev/null
+++ b/dev-python/setuptools/setuptools-62.3.4.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{8..11} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.4"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+ https://github.com/pypa/setuptools/
+ https://pypi.org/project/setuptools/
+"
+SRC_URI="
+ mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+ https://dev.gentoo.org/~mgorny/dist/python/${CPY_PATCHSET}.tar.xz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+ >=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+ >=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+ >=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+ >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_metadata-4.11.1[${PYTHON_USEDEP}]
+ ' 3.8 3.9)
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
+ ' 3.8)
+"
+BDEPEND="
+ ${RDEPEND}
+ >=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/build[${PYTHON_USEDEP}]
+ >=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+ >=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/pip[${PYTHON_USEDEP}]
+ dev-python/pip-run[${PYTHON_USEDEP}]
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+ dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+ dev-python/wheel[${PYTHON_USEDEP}]
+ ' "${PYTHON_TESTED[@]}")
+ )
+"
+PDEPEND="
+ >=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+ # remove bundled dependencies, setuptools will switch to system deps
+ # automatically
+ rm -r */_vendor || die
+
+ # remove the ugly */extern hack that breaks on unvendored deps
+ rm -r */extern || die
+ find -name '*.py' -exec sed \
+ -e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+ -i {} + || die
+
+ # apply distutils patches to the bundled distutils
+ pushd setuptools/_distutils >/dev/null || die
+ # TODO: distutils C++ patch?
+ eapply -p3
"${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+ popd >/dev/null || die
+
+ distutils-r1_src_prepare
+
+ export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+ local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+ if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+ return
+ fi
+
+ local EPYTEST_DESELECT=(
+ # network
+ # TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+
setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+
setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+ setuptools/tests/test_distutils_adoption.py
+
setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+ setuptools/tests/test_virtualenv.py::test_clean_env_install
+
setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+
'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+
setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+ # unhappy with pytest-xdist?
+
setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+ # TODO
+
setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+
setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+
setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+ setuptools/tests/test_extern.py::test_distribution_picklable
+ setuptools/tests/test_test.py::test_tests_are_run_once
+ # expects bundled deps in virtualenv
+
setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+
setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+
setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+ )
+
+ # test_easy_install raises a SandboxViolation due to
${HOME}/.pydistutils.cfg
+ # It tries to sandbox the test in a tempdir
+ HOME="${PWD}" epytest -n "$(makeopts_jobs)" setuptools
+}
