commit: aa70cf46636a6910d8cfb673f22e61491eb4df2d
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 17 18:05:52 2022 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Jun 17 18:16:02 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aa70cf46
x11-libs/libxcb: Revbump for xcb-proto multilib removal
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
x11-libs/libxcb/libxcb-1.15-r1.ebuild | 54 +++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
diff --git a/x11-libs/libxcb/libxcb-1.15-r1.ebuild
b/x11-libs/libxcb/libxcb-1.15-r1.ebuild
new file mode 100644
index 000000000000..f53663413b6f
--- /dev/null
+++ b/x11-libs/libxcb/libxcb-1.15-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="xml(+)"
+
+XORG_TARBALL_SUFFIX="xz"
+XORG_MULTILIB=yes
+XORG_DOC=doc
+
+inherit python-any-r1 xorg-3
+
+DESCRIPTION="X C-language Bindings library"
+HOMEPAGE="https://xcb.freedesktop.org/
https://gitlab.freedesktop.org/xorg/lib/libxcb";
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos
~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc selinux test +xkb"
+RESTRICT="!test? ( test )"
+SLOT="0/1.12"
+
+RDEPEND="
+ >=x11-libs/libXau-1.0.7-r1[${MULTILIB_USEDEP}]
+ >=x11-libs/libXdmcp-1.1.1-r1[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+ >=x11-base/xcb-proto-1.15.2
+ elibc_Darwin? ( dev-libs/libpthread-stubs )
+ test? ( dev-libs/check[${MULTILIB_USEDEP}] )
+"
+# Note: ${PYTHON_USEDEP} needs to go verbatim
+BDEPEND="${PYTHON_DEPS}
+ $(python_gen_any_dep '>=x11-base/xcb-proto-1.15[${PYTHON_USEDEP}]')
+ doc? ( app-doc/doxygen[dot] )
+ test? ( dev-libs/libxslt )
+"
+
+python_check_deps() {
+ python_has_version ">=x11-base/xcb-proto-1.15[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ python-any-r1_pkg_setup
+ xorg-3_pkg_setup
+}
+
+src_configure() {
+ local XORG_CONFIGURE_OPTIONS=(
+ $(use_enable doc devel-docs)
+ $(use_enable selinux)
+ )
+ xorg-3_src_configure
+}
