[gentoo-commits] repo/gentoo:master commit in: dev-vcs/rsvndump/

[Sebastian Pipping]

commit:     9e6b69f152efbec2b1f5473e67200018dd11b20e
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Tue Sep  6 13:30:34 2022 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Tue Sep  6 13:32:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9e6b69f1

dev-vcs/rsvndump: Fix compile for libdir "lib" + EAPI 8

Closes: https://bugs.gentoo.org/829622
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-3.0.30, Repoman-3.0.3

 dev-vcs/rsvndump/rsvndump-0.6.1-r1.ebuild | 49 +++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-vcs/rsvndump/rsvndump-0.6.1-r1.ebuild 
b/dev-vcs/rsvndump/rsvndump-0.6.1-r1.ebuild
new file mode 100644
index 000000000000..bbe206bd9717
--- /dev/null
+++ b/dev-vcs/rsvndump/rsvndump-0.6.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Dump a remote Subversion repository"
+HOMEPAGE="http://rsvndump.sourceforge.net";
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3+ BSD public-domain"  # rsvndump, snappy-c, critbit89
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc"
+
+RDEPEND="dev-vcs/subversion
+       dev-libs/apr
+       dev-libs/apr-util
+       sys-devel/gettext"
+DEPEND="${RDEPEND}
+       doc? ( app-text/xmlto
+               >=app-text/asciidoc-8.4 )"
+
+src_prepare() {
+       default
+
+       # We need to patch use of /usr/lib because it is a problem with
+       # linker lld with profile 17.1 on amd64 (see 
https://bugs.gentoo.org/739028).
+       # The grep sandwich acts as a regression test so that a future
+       # version bump cannot break patching without noticing.
+       if [[ $(get_libdir) != lib ]] ; then
+               grep -wq svn_prefix/lib m4/find_svn.m4 || die
+               sed "s,svn_prefix/lib,svn_prefix/$(get_libdir)," -i 
m4/find_svn.m4 || die
+               grep -w svn_prefix/lib m4/find_svn.m4 && die
+
+               grep -wq SVN_PREFIX/lib configure.ac || die
+               sed "s,SVN_PREFIX/lib,SVN_PREFIX/$(get_libdir)," -i 
configure.ac || die
+               grep -w SVN_PREFIX/lib configure.ac && die
+       fi
+
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               $(use_enable doc man) \
+               $(use_enable debug)
+}