commit: 76ccf0af91a096563c3eacbfb38b35e91a13bcdb
Author: Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 23 15:56:54 2022 +0000
Commit: Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Oct 23 16:06:43 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=76ccf0af
x11-misc/virtualgl: add 3.0.2
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>
x11-misc/virtualgl/Manifest | 1 +
x11-misc/virtualgl/virtualgl-3.0.2.ebuild | 101 ++++++++++++++++++++++++++++++
2 files changed, 102 insertions(+)
diff --git a/x11-misc/virtualgl/Manifest b/x11-misc/virtualgl/Manifest
index 017d98d4d092..4053eaf60cdf 100644
--- a/x11-misc/virtualgl/Manifest
+++ b/x11-misc/virtualgl/Manifest
@@ -1,2 +1,3 @@
DIST VirtualGL-3.0.1.tar.gz 1217488 BLAKE2B
7ed73406361a5032806a6d9196328b48e23caf4dea668f6cbbf2ebcee3a0e76925141a826072f3b317327c71773683df65d5ecb16ffd92a1c5ddb088a63a3f6f
SHA512
d953b9c31ec3608a05da0069d83e7115a42e2c98bf169dcf97bf2d271cf7a5673e32d66247f0184aa40741597ca0732edb5f7992a82c5bc48bac25f1cb1889ef
+DIST VirtualGL-3.0.2.tar.gz 1220143 BLAKE2B
72c6f46ee4c10c81516c9c3cfea610875375376050e266df3019fdfcc6426d10355292ce96cb0821e3934a8017daa8ab9a183049d714aa61c1e54a1b503527f4
SHA512
fe649460265def2858dde76fc9ad0c9183bc5ccf97da2689c43d7157d0a187f0fab784efb2ae17dbface4e7973a300e4b82f8bb7d563e80b67c3199b86068f37
DIST VirtualGL-3.0.tar.gz 1244024 BLAKE2B
f540a90cd84efa0bee5ad124cb2ded8c1b863be8b719581c5daf67afcec7ef5ef2c78720962a4d3159de91e9cba068cea18a278a3c4f7eb65c98b4f13792044c
SHA512
9d2f56d44dba936f653ecf0350c581298c4c51d6deb114570df32c044991a61313d59fb140517864e760bc6f7fd93bd27ffd35e2ff8a024243472a822d5cfd98
diff --git a/x11-misc/virtualgl/virtualgl-3.0.2.ebuild
b/x11-misc/virtualgl/virtualgl-3.0.2.ebuild
new file mode 100644
index 000000000000..a7d108eb3851
--- /dev/null
+++ b/x11-misc/virtualgl/virtualgl-3.0.2.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic systemd
+
+if [[ ${PV} == *9999 ]] ; then
+ EGIT_REPO_URI="https://github.com/VirtualGL/${PN}.git";
+ inherit git-r3
+else
+ MY_PN="VirtualGL"
+ MY_P="${MY_PN}-${PV}"
+ S="${WORKDIR}/${MY_P}"
+ SRC_URI="mirror://sourceforge/project/${PN}/${PV}/${MY_P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Run OpenGL applications remotely with full 3D hardware
acceleration"
+HOMEPAGE="https://www.virtualgl.org/";
+
+SLOT="0"
+LICENSE="LGPL-2.1 wxWinLL-3.1 FLTK"
+IUSE="ssl"
+
+RDEPEND="
+ ssl? (
+ dev-libs/openssl:0=[${MULTILIB_USEDEP}]
+ )
+ media-libs/libjpeg-turbo[${MULTILIB_USEDEP}]
+ x11-libs/libX11[${MULTILIB_USEDEP}]
+ x11-libs/libXext[${MULTILIB_USEDEP}]
+ x11-libs/libXtst[${MULTILIB_USEDEP}]
+ x11-libs/libXv[${MULTILIB_USEDEP}]
+ x11-libs/xcb-util-keysyms[${MULTILIB_USEDEP}]
+ virtual/glu[${MULTILIB_USEDEP}]
+ virtual/opencl[${MULTILIB_USEDEP}]
+ virtual/opengl[${MULTILIB_USEDEP}]
+ amd64? ( abi_x86_32? (
+ >=media-libs/libjpeg-turbo-1.3.0-r3[abi_x86_32]
+ >=x11-libs/libX11-1.6.2[abi_x86_32]
+ >=x11-libs/libXext-1.3.2[abi_x86_32]
+ >=x11-libs/libXtst-1.2.3[abi_x86_32]
+ >=x11-libs/libXv-1.0.10[abi_x86_32]
+ x11-libs/xcb-util-keysyms[abi_x86_32]
+ >=virtual/glu-9.0-r1[abi_x86_32]
+ virtual/opencl[abi_x86_32]
+ >=virtual/opengl-7.0-r1[abi_x86_32]
+ ) )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+ # Use /var/lib, bug #428122
+ sed -e "s#/etc/opt#/var/lib#g" -i doc/unixconfig.txt doc/index.html
doc/advancedopengl.txt \
+ server/vglrun.in server/vglgenkey server/vglserver_config || die
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ # Completely breaks steam/wine for discrete graphics otherwise
+ # see https://github.com/VirtualGL/virtualgl/issues/16
+ append-ldflags "-Wl,--no-as-needed"
+
+ abi_configure() {
+ local mycmakeargs=(
+ -DVGL_USESSL="$(usex ssl)"
+ -DCMAKE_INSTALL_DOCDIR=/usr/share/doc/"${PF}"
+ -DTJPEG_INCLUDE_DIR=/usr/include
+ -DCMAKE_INSTALL_LIBDIR=/usr/$(get_libdir)/VirtualGL
+ -DTJPEG_LIBRARY=/usr/$(get_libdir)/libturbojpeg.so
+ -DCMAKE_LIBRARY_PATH=/usr/$(get_libdir)
+ )
+ cmake_src_configure
+ }
+ multilib_parallel_foreach_abi abi_configure
+}
+
+src_install() {
+ cmake-multilib_src_install
+
+ # Make config dir
+ keepdir /var/lib/VirtualGL
+ fowners root:video /var/lib/VirtualGL
+ fperms 0750 /var/lib/VirtualGL
+ newinitd "${FILESDIR}/vgl.initd-r4" vgl
+ newconfd "${FILESDIR}/vgl.confd-r2" vgl
+
+ exeinto /usr/libexec
+ doexe "${FILESDIR}/vgl-helper.sh"
+ systemd_dounit "${FILESDIR}/vgl.service"
+
+ # Rename glxinfo to vglxinfo to avoid conflict with x11-apps/mesa-progs
+ # and eglinfo to veglinto because of conflict with mesa-progs[egl]
+ mv "${D}"/usr/bin/{,v}glxinfo || die
+ mv "${D}"/usr/bin/{,v}eglinfo || die
+
+ # Remove license files, bug 536284
+ rm "${D}"/usr/share/doc/${PF}/{LGPL.txt*,LICENSE*} || die
+}
