commit: af92d3bfbb7e6258eb23187221bd04cef5724e62
Author: Benda Xu <heroxbd <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 9 09:12:08 2023 +0000
Commit: Benda XU <heroxbd <AT> gentoo <DOT> org>
CommitDate: Wed Aug 9 09:19:06 2023 +0000
URL: https://gitweb.gentoo.org/proj/sci.git/commit/?id=af92d3bf
dev-python/llvmlite: add 0.40.1
Regress LLVM_MAX_SLOT back to 14. It does not compile with LLVM 15.
Signed-off-by: Benda Xu <heroxbd <AT> gentoo.org>
dev-python/llvmlite/llvmlite-0.40.1.ebuild | 63 ++++++++++++++++++++++++++++++
1 file changed, 63 insertions(+)
diff --git a/dev-python/llvmlite/llvmlite-0.40.1.ebuild
b/dev-python/llvmlite/llvmlite-0.40.1.ebuild
new file mode 100644
index 000000000..bacb0358b
--- /dev/null
+++ b/dev-python/llvmlite/llvmlite-0.40.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 llvm
+
+DESCRIPTION="Python wrapper around the llvm C++ library"
+HOMEPAGE="https://llvmlite.pydata.org/";
+SRC_URI="https://github.com/numba/llvmlite/archive/v${PV/_/}.tar.gz ->
${P/_/}.gh.tar.gz"
+S="${WORKDIR}/${P/_/}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="examples"
+
+LLVM_MAX_SLOT=14
+
+RDEPEND="
+ sys-devel/llvm:${LLVM_MAX_SLOT}
+ sys-libs/zlib:0=
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=()
+
+src_prepare() {
+ sed -i -e '/max_python/s:3\.10:3.11:' setup.py || die
+ distutils-r1_src_prepare
+}
+
+python_configure_all() {
+ # upstream's build system is just horrible, and they ignored the PR
+ # fixing it, so let's build the shared lib properly using implicit
+ # make rules
+
+ export LDLIBS=$(llvm-config --libs all)
+ export CXXFLAGS="$(llvm-config --cxxflags) -fPIC ${CXXFLAGS}"
+ export LDFLAGS="$(llvm-config --ldflags) ${LDFLAGS}"
+
+ local files=( ffi/*.cpp )
+ emake -f - <<EOF
+ffi/libllvmlite.so: ${files[*]/.cpp/.o}
+ \$(CXX) -shared \$(CXXFLAGS) \$(LDFLAGS) -o \$@ \$^ \$(LDLIBS)
+EOF
+
+ export LLVMLITE_SKIP_LLVM_VERSION_CHECK=1
+}
+
+python_test() {
+ "${EPYTHON}" runtests.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ if use examples; then
+ dodoc -r examples
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+}
