commit: 18a4726fc9a5986f578e29155b800627ca2188e6
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 17 07:55:53 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug 17 08:36:05 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18a4726f
dev-python/mypy: Bump to 1.5.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/mypy/Manifest | 1 +
dev-python/mypy/mypy-1.5.1.ebuild | 63 +++++++++++++++++++++++++++++++++++++++
2 files changed, 64 insertions(+)
diff --git a/dev-python/mypy/Manifest b/dev-python/mypy/Manifest
index dedb38212b52..5e584e657b83 100644
--- a/dev-python/mypy/Manifest
+++ b/dev-python/mypy/Manifest
@@ -1,2 +1,3 @@
DIST mypy-1.4.1.gh.tar.gz 2864808 BLAKE2B
7dfda945cf554e170d048fc4b2689aa25a57e058857e17dd052090089a7880da74a3dd552fb1b8f8fa9bd9e84f1c97e49b36075d10957c6ee12c2507fb775668
SHA512
8a20ded76d9d3f323dc607c6cfdd4814c2ab798620a0b38198c7ff79bd1fb93aef7f8d60afa6e568957fcd8d9bfdf42308da07b4b0dd6260f192131377ee6951
DIST mypy-1.5.0.gh.tar.gz 2901221 BLAKE2B
c23e0a5a5fc91a107fd11c9b0d97b0c19c671eb3aec718f216e53074bb4cdca96884611cdfdefd91189b9860ad54d84fecb468448f2819f4432f93594b2ffbae
SHA512
2b82be7948d44ef8ec6592fc5756dee66df1ee363e2607796f69f76e3db96e421dab8ba2aea4db9e976f2b05314d97a031f1d197633df34a5667f4d1dabbd70f
+DIST mypy-1.5.1.gh.tar.gz 2901212 BLAKE2B
b136cf061162bc50a48f1556763d7a1258b5a29b63a77db9190f89c56d3e85375a2b0e826d75472a0dc37df4d3391f2d85bb5f1f29c2907055a978e3c8d75906
SHA512
2c81322c0e7d9621e6d189f4d9d25d77c5fd6decbb563c8d0015e0f94ff1ff8206e5b7a38884edd3eedb99e839c03283ebfa7d86577c9f8e0d707c0cc4eb8fed
diff --git a/dev-python/mypy/mypy-1.5.1.ebuild
b/dev-python/mypy/mypy-1.5.1.ebuild
new file mode 100644
index 000000000000..515523a5daef
--- /dev/null
+++ b/dev-python/mypy/mypy-1.5.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Optional static typing for Python"
+HOMEPAGE="
+ https://www.mypy-lang.org/
+ https://github.com/python/mypy/
+ https://pypi.org/project/mypy/
+"
+SRC_URI="
+ https://github.com/python/mypy/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+
+# stubgen collides with this package: https://bugs.gentoo.org/585594
+RDEPEND="
+ !dev-util/stubgen
+ >=dev-python/psutil-4[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
+ >=dev-python/mypy_extensions-1.0.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/tomli[${PYTHON_USEDEP}]
+ ' 3.{9..10})
+"
+BDEPEND="
+ test? (
+ >=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+ >=dev-python/filelock-3.3.0[${PYTHON_USEDEP}]
+ >=dev-python/lxml-4.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-7.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-1.18[${PYTHON_USEDEP}]
+ >=dev-python/py-1.5.2[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+# this requires packaging a lot of type stubs
+export MYPY_USE_MYPYC=0
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # the majority of them require Internet (via pip)
+ mypy/test/testpep561.py
+ )
+ # Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
+ # fail with high COLUMNS values
+ local -x COLUMNS=80
+ epytest -n "$(makeopts_jobs)" --dist=worksteal
+}
