commit: 797626e99c40630329ddfbe94eb2567d2446ebd8
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 3 04:05:18 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Sep 3 04:12:27 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=797626e9
dev-python/pytest: Bump to 7.4.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pytest/Manifest | 1 +
dev-python/pytest/pytest-7.4.1.ebuild | 107 ++++++++++++++++++++++++++++++++++
2 files changed, 108 insertions(+)
diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index 033250f3e1de..50f9c0fcefd9 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -1,2 +1,3 @@
DIST pytest-7.3.2.tar.gz 1338457 BLAKE2B
4aa6ad62f654df9373427d9c19d92565a7da8d65460ee0872a30d4235e72af1ee3155871d7f7157b8e9c1173fc40bcdb87acab2b7bffdc6255cf8509e7a0bba3
SHA512
910de83f6ce47e7b1b25947050cf79e055ab04fd0c3dc3276546415684c20c8977883f16dfb913de3f339bc6284330f8a57d202c73f92b92545e45acb353b264
DIST pytest-7.4.0.tar.gz 1349733 BLAKE2B
59b9e90ab226dd317a5beeb0b189d0e323379e781dcca3fc7aa37ab7ef6d623a25f6f50e4b648cd274bdbc202e914fd393749d093a4c9d8c2f19124403d6b4fe
SHA512
48caca22c77e03cb3bca04d2f11695c48868433e6966b6f652f414b3b4405cb9dfba1ebdfd66060ba6add45609ec27b2eddd81d3739ef8e84a51b9da3c6f6099
+DIST pytest-7.4.1.tar.gz 1352174 BLAKE2B
f193cb8eee00e40d1c55a5d83856ea338c7cc9d2ed7e6bf7fc9202170a042d2de5a34663b34e11b4fdafea185c594ae5c21dd53695b5daeedc4858aab4dd7dc1
SHA512
b87e4d41026004b24aa05a39cdce33864e6ca9286894b4f94ab09ee88335bd8d82a8813328f84a0ad9d3db5e3a646d022bc4c7a94eeb281ac13c87d34d23e1da
diff --git a/dev-python/pytest/pytest-7.4.1.ebuild
b/dev-python/pytest/pytest-7.4.1.ebuild
new file mode 100644
index 000000000000..34cc63f9e938
--- /dev/null
+++ b/dev-python/pytest/pytest-7.4.1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{10..12} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="Simple powerful testing with Python"
+HOMEPAGE="
+ https://pytest.org/
+ https://github.com/pytest-dev/pytest/
+ https://pypi.org/project/pytest/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos
~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/iniconfig[${PYTHON_USEDEP}]
+ >=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ >=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+ >=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
+ ' 3.{9..10})
+"
+BDEPEND="
+ >=dev-python/setuptools-scm-6.2.3[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ $(python_gen_cond_dep '
+ dev-python/argcomplete[${PYTHON_USEDEP}]
+ >=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+ >=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.7.2[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/xmlschema[${PYTHON_USEDEP}]
+ ' "${PYTHON_TESTED[@]}")
+ )
+"
+
+src_test() {
+ # workaround new readline defaults
+ echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
+ local -x INPUTRC="${T}"/inputrc
+ distutils-r1_src_test
+}
+
+python_test() {
+ if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+ einfo "Skipping tests on ${EPYTHON}"
+ return
+ fi
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x COLUMNS=80
+
+ local EPYTEST_DESELECT=(
+ # broken by epytest args
+ testing/test_warnings.py::test_works_with_filterwarnings
+
+ # tend to be broken by random pytest plugins
+ # (these tests patch PYTEST_DISABLE_PLUGIN_AUTOLOAD out)
+ testing/test_helpconfig.py::test_version_less_verbose
+ testing/test_helpconfig.py::test_version_verbose
+ testing/test_junitxml.py::test_random_report_log_xdist
+ testing/test_junitxml.py::test_runs_twice_xdist
+
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal
+
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal_count
+
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_verbose
+
testing/test_terminal.py::TestProgressWithTeardown::test_xdist_normal
+
testing/test_terminal.py::TestTerminalFunctional::test_header_trailer_info
+
testing/test_terminal.py::TestTerminalFunctional::test_no_header_trailer_info
+
+ # unstable with xdist
+
testing/test_terminal.py::TestTerminalFunctional::test_verbose_reporting_xdist
+
+ # TODO (XPASS)
+
testing/test_debugging.py::TestDebuggingBreakpoints::test_pdb_not_altered
+
testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_simple
+
testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_twice
+
testing/test_debugging.py::TestPDB::test_pdb_with_injected_do_debug
+ testing/test_debugging.py::test_pdb_suspends_fixture_capturing
+
+ # setuptools warnings
+
testing/acceptance_test.py::TestInvocationVariants::test_cmdline_python_namespace_package
+ )
+
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ # regressions on pypy3.9
+ # https://github.com/pytest-dev/pytest/issues/9787
+ testing/test_skipping.py::test_errors_in_xfail_skip_expressions
+ testing/test_unraisableexception.py
+ )
+
+ epytest -p xdist -n "$(makeopts_jobs)"
+}
