commit: 64e95fd6308270bffcfc5b2beb2f860da82e02c9
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 2 04:21:09 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Oct 2 04:21:09 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=64e95fd6
dev-python/pylint: Bump to 3.0.0_beta0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pylint/Manifest | 1 +
dev-python/pylint/pylint-3.0.0_beta0.ebuild | 83 +++++++++++++++++++++++++++++
2 files changed, 84 insertions(+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index ed9abcb6dc9f..620535e9ca44 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1,3 +1,4 @@
DIST pylint-2.17.5.gh.tar.gz 1413718 BLAKE2B
7ba0a6cb78cdef5f16e80d98d1b02f41ae700c44365de26a0a650b60fe95b4b806e36786d16ec50ed5c78c8b86c13afe8e7fe215dd938df654c2883d5493d318
SHA512
431e722d027b03f1b657841ccaba43233961e810aecfe1a679e3ba4ba92fea94f28524195861a6fd4fe6fc6267a1af6489b9b69e5e30f919ac3a476fd35698ec
DIST pylint-2.17.6.gh.tar.gz 1415348 BLAKE2B
d760a81cc8a453a081f1b0e3845c5a0b608b8109863665361990da127323c877e8e02ed9c1aca656fa84dd49941b23652fc465177a3e347942047299ebb86a32
SHA512
1e1bba425d295f9d267ef439f4f402dfc7284ee57ac41c222ac39e502c66bbac60c9afb0024ca4236de7cc7130ac733c781f5ee98670fae054005a8d69107123
DIST pylint-2.17.7.gh.tar.gz 1415651 BLAKE2B
9b2edea7d7d9e05fd265749cb1e50e77513e382518dc16bf654861e66564c55a430193ab1f538cb23e31e85d2130784c648ba185d62139c6df752ca54f0fc09d
SHA512
514fe9d244a58e21fade66f0e343f2162a2fc2f99d7197f4d91801250c13fde2ddc365f92a274d89d602689466a12bac3ff9dd364ce15891171ef86d6313aba2
+DIST pylint-3.0.0b0.gh.tar.gz 1421208 BLAKE2B
e58859e85b5001236a7f92060bca3e828957c8a24b3f0981cac795f0a0ce1af3d0be3ab8cc45c9e7fee173f988598e23fb3b9bc3c257d2e354c7d1c621ae7301
SHA512
265f29d28879c09320a8aa3d235873d96505a2472fb9b41ac0f11fa453c2e4d3fb57133bc588583ac82bdaad895b1cafe828f5662d3700baf6eaf6c3f22817db
diff --git a/dev-python/pylint/pylint-3.0.0_beta0.ebuild
b/dev-python/pylint/pylint-3.0.0_beta0.ebuild
new file mode 100644
index 000000000000..5046bb6252b7
--- /dev/null
+++ b/dev-python/pylint/pylint-3.0.0_beta0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+ https://pypi.org/project/pylint/
+ https://github.com/pylint-dev/pylint/
+"
+SRC_URI="
+ https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+# Make sure to check
https://github.com/pylint-dev/pylint/blob/main/pyproject.toml#L34 on bumps
+# Adjust dep bounds!
+RDEPEND="
+ <dev-python/astroid-3.1[${PYTHON_USEDEP}]
+ >=dev-python/astroid-3.0.0[${PYTHON_USEDEP}]
+ >=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+ <dev-python/isort-6[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ >=dev-python/GitPython-3[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
'tests/test_functional.py::test_functional[dataclass_with_field]'
+
+ # incompatible versions of numpy/scikit-learn?
+ 'tests/test_functional.py::test_functional[no_name_in_module]'
+ 'tests/test_functional.py::test_functional[shadowed_import]'
+ )
+ local EPYTEST_IGNORE=(
+ # No need to run the benchmarks
+ tests/benchmark/test_baseline_benchmarks.py
+ )
+
+ rm -rf pylint || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p timeout
+}
+
+python_install_all() {
+ if use examples ; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+
+ distutils-r1_python_install_all
+}
