commit: da0d7dec89fd5e6040142b058e7124fed129161b
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 14 18:36:43 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Oct 14 18:36:43 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=da0d7dec
dev-python/aws-xray-sdk: Bump to 2.12.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/aws-xray-sdk/Manifest | 1 +
dev-python/aws-xray-sdk/aws-xray-sdk-2.12.1.ebuild | 83 ++++++++++++++++++++++
2 files changed, 84 insertions(+)
diff --git a/dev-python/aws-xray-sdk/Manifest b/dev-python/aws-xray-sdk/Manifest
index 18e6c1166254..d2ee6c099032 100644
--- a/dev-python/aws-xray-sdk/Manifest
+++ b/dev-python/aws-xray-sdk/Manifest
@@ -1 +1,2 @@
DIST aws-xray-sdk-python-2.12.0.gh.tar.gz 275773 BLAKE2B
a78ac201524e70a342100c2e76e93bb02ed76e183dfca2e8737230061182d94c9a7f4eba183bc731d2ed79a8e4dda486ea09cb304f4cd58da56d712b8e6c5749
SHA512
0616369f95bf0de710ab5fb868d1a84280bcc1180cc205e6a6e0c405eae131fb861de75fea00c9c1be4e163b9d292cc27e08f624c7b6981ba4a3b8d99dbbb63c
+DIST aws-xray-sdk-python-2.12.1.gh.tar.gz 275525 BLAKE2B
7aae0cc3d6b733ee80b553d087bd85d02329c7da3a8902cb428823af4a53d47a14089a274cfccdfb197a77370dcb71775e1d111bb76205a1f09f9b60a5c92967
SHA512
3c830cf81f353a2805b641bda3d38d72a1286d413e0cd087bfeac78bfe00e7853c19ddab96f18275e7fd95317c2a6650d5e4b287d63c1d3900b25414a525c3dc
diff --git a/dev-python/aws-xray-sdk/aws-xray-sdk-2.12.1.ebuild
b/dev-python/aws-xray-sdk/aws-xray-sdk-2.12.1.ebuild
new file mode 100644
index 000000000000..8ea6369f4aae
--- /dev/null
+++ b/dev-python/aws-xray-sdk/aws-xray-sdk-2.12.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+MY_P=aws-xray-sdk-python-${PV}
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="
+ https://github.com/aws/aws-xray-sdk-python/
+ https://pypi.org/project/aws-xray-sdk/
+"
+SRC_URI="
+ https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+ >=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+ dev-python/wrapt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/bottle[${PYTHON_USEDEP}]
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/webtest[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+ local -x AWS_SECRET_ACCESS_KEY=fake_key
+ local -x AWS_ACCESS_KEY_ID=fake_id
+
+ local EPYTEST_DESELECT=(
+ # Internet access
+ tests/test_patcher.py::test_external_file
+ tests/test_patcher.py::test_external_module
+ tests/test_patcher.py::test_external_submodules_full
+ tests/test_patcher.py::test_external_submodules_ignores_file
+ tests/test_patcher.py::test_external_submodules_ignores_module
+ # benchmark
+ tests/test_local_sampling_benchmark.py
+ # Fails, probably because above is ignored
+ tests/test_async_local_storage.py::test_localstorage_isolation
+ tests/test_async_recorder.py::test_capture
+ tests/test_async_recorder.py::test_concurrent_calls
+ tests/test_async_recorder.py::test_async_context_managers
+ )
+ local EPYTEST_IGNORE=(
+ # unpackaged deps
+ tests/ext/aiobotocore
+ tests/ext/pg8000
+ tests/ext/psycopg2
+ tests/ext/pymysql
+ tests/ext/pynamodb
+ tests/ext/sqlalchemy_core/test_postgres.py
+ tests/ext/django/test_db.py
+ # Internet access
+ tests/ext/httplib
+ tests/ext/httpx
+ tests/ext/requests
+ # requires old package vesions
+ tests/ext/aiohttp
+ tests/ext/django
+ tests/ext/flask_sqlalchemy
+ tests/ext/sqlalchemy
+ )
+
+ epytest -p no:django
+}
