[gentoo-commits] repo/gentoo:master commit in: dev-python/responses/

[Michał Górny]

commit:     92311174c66452f8aee07966ce6c19b04fad639f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 15 05:39:27 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Nov 15 05:55:08 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=92311174

dev-python/responses: Bump to 0.24.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/responses/Manifest                |  1 +
 dev-python/responses/responses-0.24.1.ebuild | 46 ++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+)

diff --git a/dev-python/responses/Manifest b/dev-python/responses/Manifest
index 38e571fb6d57..60d57bcecc15 100644
--- a/dev-python/responses/Manifest
+++ b/dev-python/responses/Manifest
@@ -1 +1,2 @@
 DIST responses-0.23.3.tar.gz 73737 BLAKE2B 
e246dc09832f996b085f84b4b90d58709dc283a51e6de6f67a50096f1550b9e11f2e8f809043e366d7dc1140511bc9be16aeeaa5218da6fc05b1b60a1c924800
 SHA512 
334beb4a0cdabce2bedd1e336c4af04a38818b8b90c9d0ffbbf3445f72f8c57cc03278e832c6442f9ecfec24723c567bfba76ad25c45cf2924e42d5108c51c7a
+DIST responses-0.24.1.tar.gz 77530 BLAKE2B 
6f4482a0b7f7388506782286e35e716b4fcb746f6d562cba3e5b095163e380e0921f71f808c4729c2c6fb03c3efa1005ae6dbab9d3b61275af720b215b4e4181
 SHA512 
fd97f56055da4e31fc9866e4fdb7d68b2273cac25c6d882811268daf5f474d21897454b790122ed4c12e18032b9ae2c032b958402c6840b46ec38fdd7306033f

diff --git a/dev-python/responses/responses-0.24.1.ebuild 
b/dev-python/responses/responses-0.24.1.ebuild
new file mode 100644
index 000000000000..80fb7a77fc3d
--- /dev/null
+++ b/dev-python/responses/responses-0.24.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Utility for mocking out the Python Requests library"
+HOMEPAGE="
+       https://pypi.org/project/responses/
+       https://github.com/getsentry/responses/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 
~riscv ~s390 ~sparc ~x86"
+
+# tomli backend is optional now, with pyyaml being the new default.
+# However, keeping it unconditional here for backwards compatibility.
+RDEPEND="
+       dev-python/pyyaml[${PYTHON_USEDEP}]
+       <dev-python/requests-3[${PYTHON_USEDEP}]
+       >=dev-python/requests-2.30.0[${PYTHON_USEDEP}]
+       $(python_gen_cond_dep '
+               dev-python/tomli[${PYTHON_USEDEP}]
+       ' 3.10)
+       dev-python/tomli-w[${PYTHON_USEDEP}]
+       <dev-python/urllib3-3[${PYTHON_USEDEP}]
+       >=dev-python/urllib3-1.25.10[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+       test? (
+               dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       epytest -p pytest_httpserver
+}