commit: 5ce685715302268e28c60e4bdabb8a0412196c65
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 15 08:20:58 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Dec 15 08:59:13 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5ce68571
dev-python/statsmodels: Bump to 0.14.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/statsmodels/Manifest | 1 +
dev-python/statsmodels/statsmodels-0.14.1.ebuild | 85 ++++++++++++++++++++++++
2 files changed, 86 insertions(+)
diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
index 679496d3c80e..b10c9c616d02 100644
--- a/dev-python/statsmodels/Manifest
+++ b/dev-python/statsmodels/Manifest
@@ -1,2 +1,3 @@
DIST statsmodels-0.13.5.tar.gz 18364957 BLAKE2B
8357416b015b152612aca88a9ff42b81db4d97f61b1c255bc2baf8978440cd43fa1a5301d1c60e92b3a634008c5c001c00770685864d296587ff75e37d29ff4f
SHA512
9aeeea80c69f52459140179523a0155429834b2951325c9781b28f8c4cbbd0593ff1867e2212078f2b898e4da953689c2fe78183d3c7959caa874e9d758b4ea4
DIST statsmodels-0.14.0.tar.gz 19374614 BLAKE2B
b24c8c146ea9ed393da8e839e3c9a80b1ddaa6fe319204f4440b3435c756911bc1b6405544c6ab8e4370fd378ba26715da743e4d082af7774b8cefa8649d6c58
SHA512
876cc45eb4b5badee2ff859df8a45ce7c4f6ab2973d481f58c5b7906ebcdbb56a64769d5dd7a38c7b7415a4ee7cf98cf300b8c623bda9df001b982ff6844d1fd
+DIST statsmodels-0.14.1.tar.gz 20309647 BLAKE2B
ef9b70671b78eb45b48997c5a8ea35828b7722b31a6c77d55b81f4aad6ddb3608305a3319a0d284797654ef2bbd5f25416459450a6b26be56b9e3e3137fccac8
SHA512
e382ca807205e2aeff76dd22b42e7824914472588ea040d90835fd46e0c993e155828c58e81f53f9539ad9bdf195bbbd1a49a45658187498d60287374112fd68
diff --git a/dev-python/statsmodels/statsmodels-0.14.1.ebuild
b/dev-python/statsmodels/statsmodels-0.14.1.ebuild
new file mode 100644
index 000000000000..ac0f7f2f35e8
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.14.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="
+ https://www.statsmodels.org/stable/index.html
+ https://github.com/statsmodels/statsmodels/
+ https://pypi.org/project/statsmodels/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux
~x86-linux"
+IUSE="examples"
+
+DEPEND="
+ >=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.3[${PYTHON_USEDEP}]
+"
+RDEPEND="
+ ${DEPEND}
+ >=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+ >=dev-python/pandas-0.25[${PYTHON_USEDEP}]
+ >=dev-python/patsy-0.5.2[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ ${DEPEND}
+ >=dev-python/cython-0.29.33[${PYTHON_USEDEP}]
+ >=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+ 'dev-python/ipykernel' \
+ 'dev-python/jupyter-client' \
+ 'dev-python/matplotlib' \
+ 'dev-python/nbconvert' \
+ 'dev-python/numpydoc'
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ export VARTEXFONTS="${T}"/fonts
+ export MPLCONFIGDIR="${T}"
+ printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ local -x MKL_NUM_THREADS=1
+ local -x OMP_NUM_THREADS=1
+ local EPYTEST_DESELECT=(
+ # note that test path should be without "statsmodels/" prefix
+ imputation/tests/test_mice.py::TestMICE::test_combine
+ stats/tests/test_mediation.py::test_mixedlm
+ "stats/tests/test_corrpsd.py::test_corrpsd_threshold[0]"
+ )
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ epytest statsmodels
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x /usr/share/doc/${PF}/examples
+ dodoc -r examples
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Plotting functionality" "dev-python/matplotlib"
+}
