[gentoo-commits] repo/gentoo:master commit in: dev-libs/qcoro5/

[Andreas Sturmlechner]

commit:     7a0c009494e3baac64d8a4a77e7fb40b98175bcf
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 25 15:16:07 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Dec 25 17:03:51 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7a0c0094

dev-libs/qcoro5: add 0.10.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/qcoro5/Manifest             |  1 +
 dev-libs/qcoro5/qcoro5-0.10.0.ebuild | 68 ++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-libs/qcoro5/Manifest b/dev-libs/qcoro5/Manifest
index f2dd06a4fa85..be781223f1cb 100644
--- a/dev-libs/qcoro5/Manifest
+++ b/dev-libs/qcoro5/Manifest
@@ -1 +1,2 @@
+DIST qcoro5-0.10.0.tar.gz 150114 BLAKE2B 
8a552dc3a0e4a5963c7c9fd0638f336e6ad99491a54df3bb8ddaa6b0ee1fe8e4c6b7ffc26c25cef543e796c54bc4c625a0915755f4b538f489bc61fcd8310a6a
 SHA512 
de2e55256d3c9d35fec3ef6dc78128801b70a5e5b8ff0f3a6f235dac17f349ea44207a7c9f35375215dbeea04cb67c3412d505d0a8a95f2b926775f804a02649
 DIST qcoro5-0.9.0.tar.gz 143270 BLAKE2B 
0fbd4e606edb3142b440486412889ebbefd3b5ac47eeba12747ea5314acf5d4088463fe0a03c44d787510c1355c9f5f9b060d8f2fd07e668fb2f397c2f139099
 SHA512 
f708e1a82861c39434d6934172246c3280864e933b333b56c0471f1a629f9da65554d1508af4291ac2257ad8df2040655394ae5525d728710de5bd83cef8fbee

diff --git a/dev-libs/qcoro5/qcoro5-0.10.0.ebuild 
b/dev-libs/qcoro5/qcoro5-0.10.0.ebuild
new file mode 100644
index 000000000000..2a91bf4d4ad2
--- /dev/null
+++ b/dev-libs/qcoro5/qcoro5-0.10.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/danvratil/${PN/5/}";
+else
+       
SRC_URI="https://github.com/danvratil/${PN/5/}/archive/refs/tags/v${PV}.tar.gz 
-> ${P}.tar.gz"
+       S="${WORKDIR}/${P/5/}"
+       KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="C++ Coroutine Library for Qt5"
+HOMEPAGE="https://qcoro.dvratil.cz/ https://github.com/danvratil/qcoro";
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="dbus examples +network qml test testlib websockets"
+
+REQUIRED_USE="examples? ( network ) test? ( testlib )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       dev-qt/qtcore:5
+       dbus? ( dev-qt/qtdbus:5 )
+       network? ( dev-qt/qtnetwork:5 )
+       qml? ( dev-qt/qtdeclarative:5= )
+       testlib? ( dev-qt/qttest:5 )
+       websockets? ( dev-qt/qtwebsockets:5 )
+"
+DEPEND="${RDEPEND}
+       examples? (
+               dev-qt/qtconcurrent:5
+               dev-qt/qtnetwork:5
+               dev-qt/qtwidgets:5
+       )
+       test? (
+               dev-qt/qtconcurrent:5
+               dev-qt/qttest:5
+       )
+"
+
+src_configure() {
+       local mycmakeargs=(
+               -DUSE_QT_VERSION=5
+               -DQCORO_BUILD_EXAMPLES=$(usex examples)
+               -DQCORO_WITH_QTDBUS=$(usex dbus)
+               -DQCORO_WITH_QTNETWORK=$(usex network)
+               -DQCORO_WITH_QML=$(usex qml)
+               -DQCORO_WITH_QTQUICK=$(usex qml)
+               -DQCORO_WITH_QTTEST=$(usex testlib)
+               -DBUILD_TESTING=$(usex test)
+               -DQCORO_WITH_QTWEBSOCKETS=$(usex websockets)
+       )
+       cmake_src_configure
+}
+
+src_install() {
+       if use examples; then
+               docinto examples
+               dodoc -r examples/*
+       fi
+       cmake_src_install
+}