commit: 182886a8debfd576637ea49e9b2723cc83e4cf2c
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 7 06:07:41 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jan 7 06:15:59 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=182886a8
dev-python/libsass: Bump to 0.23.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/libsass/Manifest | 1 +
dev-python/libsass/libsass-0.23.0.ebuild | 62 ++++++++++++++++++++++++++++++++
2 files changed, 63 insertions(+)
diff --git a/dev-python/libsass/Manifest b/dev-python/libsass/Manifest
index 1e50ee28909d..48dfb86bed9d 100644
--- a/dev-python/libsass/Manifest
+++ b/dev-python/libsass/Manifest
@@ -1 +1,2 @@
DIST libsass-python-0.22.0.gh.tar.gz 55135 BLAKE2B
8495462fa8e6a68bf73ecdf68771c577bad1affa1121c1781dac41c912aae731df88c2b1d1a4ef363e50a98ff1b471e7c45562faa6f2425e8ec5f47f9cf76c6c
SHA512
13914b60fe19fc70d197a948a2bc83f7646e4acaa45caed6df68bf2eb10e0a7ef811cdbbcc7a4338f9c1433cba8e316146c20072dc4ff34f51e094ead1bfdcd7
+DIST libsass-python-0.23.0.gh.tar.gz 54783 BLAKE2B
b2113d295370391c6b92c2561873cc1c58c3acdcc5c4adb6c50e717bb963bbf5d4e29e97290e2b4743508c0f1a73be373233205a79c31b6f6a0262559adcf924
SHA512
fb0836cce26ef8cdfb90cb50842e66f83ed47d06327272a49db3f2cf4b7f1bc29560d0126f00ff13db626d0624ff154c342a0f2433802d4c1b582b8d74a50337
diff --git a/dev-python/libsass/libsass-0.23.0.ebuild
b/dev-python/libsass/libsass-0.23.0.ebuild
new file mode 100644
index 000000000000..a076bac3b66a
--- /dev/null
+++ b/dev-python/libsass/libsass-0.23.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+MY_P=libsass-python-${PV}
+DESCRIPTION="A straightforward binding of libsass for Python"
+HOMEPAGE="
+ https://github.com/sass/libsass-python/
+ https://pypi.org/project/libsass/
+"
+SRC_URI="
+ https://github.com/sass/libsass-python/archive/${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+ >=dev-libs/libsass-3.6.5
+"
+RDEPEND="
+ ${DEPEND}
+"
+BDEPEND="
+ test? (
+ dev-python/PyQt5[testlib,${PYTHON_USEDEP}]
+ dev-python/werkzeug[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+ export SYSTEM_SASS=1
+ # https://bugs.gentoo.org/881339
+ # the package is applying C++ flags to C sources
+ sed -i -e "s:'-std=gnu++0x',::" -e "s:'-lstdc++'::" setup.py || die
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # probably broken by removal of sassc
+ sasstests.py::SasscTestCase::test_sassc_stdout
+ # skip the pip tests because they need an internet connection
+ # not relevant for gentoo anyway
+ sasstests.py::DistutilsTestCase::test_build_sass
+ sasstests.py::DistutilsTestCase::test_output_style
+ )
+
+ epytest sasstests.py
+}
