commit: a69334018dac557f820a22b7802b6d80a81dcf8b
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 10 04:38:57 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jan 10 04:38:57 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a6933401
dev-python/trio: Bump to 0.24.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/trio/Manifest | 1 +
dev-python/trio/trio-0.24.0.ebuild | 67 ++++++++++++++++++++++++++++++++++++++
2 files changed, 68 insertions(+)
diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index 3d552d43f288..16d9b2fb18a5 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1 +1,2 @@
DIST trio-0.23.2.gh.tar.gz 592068 BLAKE2B
4f985c03528343f6091988984b081399f4a661f73896af13b4face0c7eab242d763d4ae964d36f8c9d0fcce797518283a492edd556a83af10502c8fc617cdb91
SHA512
a77b2a20459eb4989e9db6d21b06472b3cce51f4cb28cc6f3ab2f3e1684b3ccb37775e0d60af1f121c63a54fb92d62955f76109c922879234f0a21ce8c9f20c1
+DIST trio-0.24.0.gh.tar.gz 592652 BLAKE2B
c102c6b6e25b497a5823b58b926f43d06905a8aaa41434d9503c127cb1b26a3c58594edc90e48e9acea6e6ffbc36a2d02a9f1805b14ba65a77ffedcbb8cf48f8
SHA512
3f52e770a19c45b5227ffd34e7ae4664ee739dbae81c09e1e4bf2bd3eddb414ff9ab32dd2b18d59e420a18660a2f7db7ad2cda9f725729dda7e99f7a89b66bbc
diff --git a/dev-python/trio/trio-0.24.0.ebuild
b/dev-python/trio/trio-0.24.0.ebuild
new file mode 100644
index 000000000000..5d1d9d45c09b
--- /dev/null
+++ b/dev-python/trio/trio-0.24.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+ https://github.com/python-trio/trio/
+ https://pypi.org/project/trio/
+"
+SRC_URI="
+ https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/exceptiongroup[${PYTHON_USEDEP}]
+ ' 3.10)
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/outcome[${PYTHON_USEDEP}]
+ >=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
+ dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ >=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+ >=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+# Bug https://bugs.gentoo.org/916756
+# distutils_enable_sphinx docs/source \
+# dev-python/immutables \
+# dev-python/sphinxcontrib-trio \
+# dev-python/sphinx-rtd-theme \
+# dev-python/towncrier
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Times out on slower arches (ia64 in this case)
+ # https://github.com/python-trio/trio/issues/1753
+ tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+ # requires ruff
+ _tests/tools/test_gen_exports.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ rm -rf trio || die
+ epytest -p trio._tests.pytest_plugin \
+ -m "not redistributors_should_skip" \
+ --pyargs trio \
+ --skip-optional-imports
+}
