commit: 1c9d22c71a241f9dd89d6039d8a286cc8c283f6d
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 13 08:34:28 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 13 09:28:27 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c9d22c7
dev-python/django: Bump to 3.2.23
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-3.2.23.ebuild | 109 +++++++++++++++++++++++++++++++++
2 files changed, 111 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 47b7b7862bde..c4bbedcd7c9d 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,5 +1,7 @@
DIST Django-3.2.22.checksum.txt 2582 BLAKE2B
bb9fe0f9e8af1142a1dae1b5c53422ddeb186d8c13389cbdbeaa9585be519d3c1604e8af797be1cf75261041799f4e213dfb5764559f0c4765d8e33580acd614
SHA512
6b30f0caed55b966c1a1c83b1f733f7d2098f33d5e84670f2cf3729e584e6b15c6439589bbe26670aa2a6e286f938305bc5457bc4fbc5ba86a128938afcab076
DIST Django-3.2.22.tar.gz 9827193 BLAKE2B
164d766ee16c92c7f47a45c3a426d54a8bc0007a9387594d61fda77d143f51142389ecc4817f2fcadeaaa55ac3bcf381331cb9ca2305d0915bef1e10101dcd16
SHA512
a2c81dc63609be521aa1a74c85be93e3263380d533c0d6888b4ba20f5a12f0d99c329286c99896734fc9a9b111d873934e4f553d18f246911cbfd65feea73b46
+DIST Django-3.2.23.checksum.txt 2563 BLAKE2B
59bc9c0946de84be99057be9f044e59f7fd87d1a4043041033916fbc0052a8d4f8d2b02bfe591374fba7bf54c6d2ea1ee8f4739bdbd49a369312e8792fe2a1f7
SHA512
356379166f9375175b896cf07ff2debbbed3cff859597cf8600a3e14e0660c15914f561c54bba2bdb38742c5ec4f9f1bd412baef5f6271548a1f76485f61eaea
+DIST Django-3.2.23.tar.gz 9834665 BLAKE2B
365ab5101e610ed1d0ed504cd538cc90a8d5d0730fcb43dab12b8f0ce1d1f2a6d42e4e36eccaf84d242e4fc9d9c75fefc5062ac1e8d077cb784eea741df716ee
SHA512
a252e4000c932a906eef22d0cb91a9dcb802eb65bbe0fc0eb881216b6801dbef5123b21f51f3208def155852c20e8d7e9adc8339b6386fc49bbc00f7c4d2d4ba
DIST Django-4.1.12.checksum.txt 2582 BLAKE2B
67b101ef7b11fe1ad47872b9bbb26851b20db304145cebbf3f836bcd7505aa5282b54d8541a468871fa0489445ce282dc030f83241db3a1824e5e2d3949257b9
SHA512
d226527d67c98b1641ea63899c93e3be21855f7be3270ab98e2ad1580d38edf1ab209d92964a8b0ba5b15a2466af96fe1838914b0aaa0953fbc46f21a25587fb
DIST Django-4.1.12.tar.gz 10502350 BLAKE2B
1e13d4a7c00d7fa49c41bbdc3e69604e462de9ebdb302097ca610cd7d791ebb1ac4bdb610b791e7d578125df83be0551b5d98fbeace630a042a8101689cb9d56
SHA512
63211a82f55b8c7ef0d8f9d09bfba926c2dc59ab7bacded517c4c3014c671ed55d0d5552678d1eae350d3d66f27dde96aed0a5e2aa1ae5f6e1c98ccf138ccc1d
DIST Django-4.2.8.checksum.txt 2553 BLAKE2B
552fd9dc6740baabc434a4d069c0a22c49e36661da58face4853c8ca5f34254314a3ca85048d5a4786a9a15ed27c8f73016c9a3d7bcf63dc617373e243a3ee77
SHA512
e3808f5d28fb95aa6ebbcc393161cc69cb948ab4ebe0dcc7a4f6ca8964e4a3dacf4aa185688d21b5d176456621f609e95909cbbc4abe6528f72afe3b644b5ea3
diff --git a/dev-python/django/django-3.2.23.ebuild
b/dev-python/django/django-3.2.23.ebuild
new file mode 100644
index 000000000000..6fd28d4ce937
--- /dev/null
+++ b/dev-python/django/django-3.2.23.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://github.com/django/django/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+ verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/selenium[${PYTHON_USEDEP}]
+ dev-python/tblib[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.1-bashcomp.patch
+ "${FILESDIR}"/django-3.2.19-py311.patch
+ # needed for Python 3.11
+ "${FILESDIR}"/django-3.2.20-urlsplit.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+python_prepare_all() {
+ # Fails because of warnings
+ sed -i 's/test_dumpdata_proxy_with_concrete/_&/'
tests/fixtures/tests.py || die
+ # TODO: this suddenly started failing
+ sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2
||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc
dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+}
