commit: 7ba387c0ffea601ba057f00d23bfe5ee446a3317
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May 7 17:28:10 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May 7 17:45:36 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ba387c0
dev-python/django: Bump to 4.2.13
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-4.2.13.ebuild | 101 +++++++++++++++++++++++++++++++++
2 files changed, 103 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index f84088e398c0..b4d54ae454b3 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -2,6 +2,8 @@ DIST Django-3.2.25.checksum.txt 2560 BLAKE2B
e082c588f4e124c9d71c1914e475fd70ed9
DIST Django-3.2.25.tar.gz 9836336 BLAKE2B
586520e0689b2594dd8ce4abb173418aedfde80cc84012d2a4207cbfc67120cbf405a8dfc8d069bb946f027f0eef22b233bd3b3ce569b01ea8fdc7836a6e530f
SHA512
ccba83abd1777123186d685e21b96f41abf216a692d18ffe764d2e519eb9d1f6011d08c86b3affdd891591ca4ed7fee27ffa4750d19b486ca775ee680fdb0cb1
DIST Django-4.2.11.checksum.txt 2560 BLAKE2B
75359ca138515642b4cb4bb17f4e5f18f94d9c4b5a98fe62f4813068d3dfccfa6c3fe1a2ae9ec24758610d0c5c8fe899b54f39b9cd657a92635e8cd7c6f7dcf0
SHA512
9ab3700f2675380dd6e18b5cc1ebbf4fbbd31680079e9232f96133810956e3ab5a46eefa45103a90bbec9d0ba85cc54f5cc2dd4f3d69c64960724f2821ecf3f3
DIST Django-4.2.11.tar.gz 10426858 BLAKE2B
bce1611700383831138a467cfdc3ad2780385429be040d197cb757206c3d1b4c82075cf6766f8222d0c061ee7c0a7a48caf8cd28e8fe6271c39dc47899c4b276
SHA512
5842f0c2592b695ecfd7f00d250075cb9581efc8a7f389f155dbac74d80ac7899f600ffba0d51e3391f15c4a1444554d901b8a673a1091ab7269e24862122ef0
+DIST Django-4.2.13.checksum.txt 2578 BLAKE2B
c4dee2c255a77da0655f685852bfac937e6afbfa32c6f5048916675d806c1d9218ff40117c99d7e63ee06b05dd88af4db9460672c3628c948cb17e5ca2f56817
SHA512
0994eef854b991c2db290712aff892e900ef3bab84607e385b4f78e3213b816739e42d5010afaaf30f6c68d5bc52b509b7c6e797e8e87db499a49f75b4cfd232
+DIST Django-4.2.13.tar.gz 10430886 BLAKE2B
09e8743de500f11c32c540d23d9aae1377c83177089732c78c03501dc560fd7b4316d6032534c923c354539421e519ed8439fc09d61500cea479c9eaf115f160
SHA512
2d141e2d710dbd55999db9c7005ca4a8d291dad57f0ef246eb41d4ffed76e62035b36969c5f338c3158ccd2d1677eb23de0b8f783606b4c62a3ee45e8988b712
DIST Django-5.0.4.checksum.txt 2570 BLAKE2B
dd60e743933312e8744c89a9602acf6643e778cf23d1ab303845f52a2040ff9de73b843c0facf15e8aecc61d9b29f597d76de1e015e7e5a111668fbeb1f84b99
SHA512
9a180082a1735f5d62b51acaf1bd23941d921208d6e3ea14439ceb29603f35860e0307c0b18c1b17d9a155498ef50943e10bf352090f0b6408c5921655d1f992
DIST Django-5.0.4.tar.gz 10638006 BLAKE2B
81796ec0ba285bebe2c3a4b6d3bfce39e87ad39c01fb450bd66e4eb76c167d08a16e857156d45bce95ac30121fe5855dd7493beb4dcf7628255d729e0d1a2048
SHA512
322b0de4e9e533831937b9f50929e150d9c1ff3045e92b3530d49708df05ad0139819a1056c3def529e93826d26ef8e04f1ced655525fe8c9c2d449c2c701f28
DIST Django-5.0.6.checksum.txt 2568 BLAKE2B
c4c94e1a245248ed59707fb8aeb97a8379e679c50829d0470eefd2f870de32d5b57cb4841ac44809483993bc515514c3e2b0cdf0f1768681a4ba1930e2d278a3
SHA512
231954ae528beff69fbfa385aba192f19d56e862f1a2e5e40ccbba60ce31b59a075af31d75ab9e5767c9405a37f14fd3c5c41e74f60f6b7d6821391a43992301
diff --git a/dev-python/django/django-4.2.13.ebuild
b/dev-python/django/django-4.2.13.ebuild
new file mode 100644
index 000000000000..3d93ca48aced
--- /dev/null
+++ b/dev-python/django/django-4.2.13.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 multiprocessing optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://github.com/django/django/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+ https://dev.gentoo.org/~mgorny/dist/python/django-4.2.8-pypy3.patch.xz
+ verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ <dev-python/asgiref-4[${PYTHON_USEDEP}]
+ >=dev-python/asgiref-3.6.0[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+ sys-libs/timezone-data
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/selenium[${PYTHON_USEDEP}]
+ dev-python/tblib[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20230606 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/django-4.0-bashcomp.patch
+ "${WORKDIR}"/django-4.2.8-pypy3.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite \
+ -v2 --parallel="${EPYTEST_JOBS:-$(makeopts_jobs)}" ||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:0
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc
dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+}
