commit: 15b471eed0f80cb0d0da2bcc98a09952bdfc54eb
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat May 11 20:55:51 2024 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat May 11 20:55:51 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=15b471ee
dev-util/diffoscope: add 266
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-util/diffoscope/Manifest | 1 +
dev-util/diffoscope/diffoscope-266.ebuild | 124 ++++++++++++++++++++++++++++++
2 files changed, 125 insertions(+)
diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 30039eb932d0..0a8e75dbbd23 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -2,3 +2,4 @@ DIST diffoscope-257.tar.bz2 3112404 BLAKE2B
cdd7901bdb7cfddb77d165d0084bfc4d9ad1
DIST diffoscope-263.tar.bz2 3139927 BLAKE2B
6d13b9a657c4a7618d24487096a0fb94034f4ea2b84384b388dc8441ebe68f8de12dd7a34ec0075bd03ca3d437e65a23fc086184ba7c3764682390f6290a17e4
SHA512
41c5495bd4d4f4a0c340bac444f3cbc4a9b6180227efc02d593590a50b47acd06dc755875419da3a52d8aa831733d76450388c29e856d428b159d3c2c793de1b
DIST diffoscope-264.tar.bz2 3141558 BLAKE2B
28e50c327b606053d378633bfabd262d12fe8d34778bb1451e7d34d6525ddc9ea3e72907cb948072a8466c36841a9b4d70041b7fbd099924e1dd61a472a7bac8
SHA512
e79e8db1a3a6503f871ed2686110434d1c8b43758d3eb3fd1c98bb6dabe2792297712950470134c592bb6efc4ca741277f3158597381bbdea23945de6adfa1aa
DIST diffoscope-265.tar.bz2 3143847 BLAKE2B
754124472a37d5dc5208b1dce13cda726dc7868db5c1880db3d6228afffa580b73a4420a625e84d8791fe60ddd4451128d647e7ddc3a5f25ae63271947e2780a
SHA512
6c8dd45971966dc965242ffec3061f6c29d0b7bd2367e92aab5a03f4caba99b1f8dde514884d89c6442bdc86afec4deb11c914ffc4fa84e34bace672ff4aefa0
+DIST diffoscope-266.tar.bz2 3148610 BLAKE2B
28090b8a1e2315f9df43d254d3dbd4ed8f6d4ba4d259c764f53b84137ac0b3dc97b51df56ba595eee950c54974e9b6109c423392d198e277d520f11559ecd78e
SHA512
2eb7cbd333b6559ba0f66647184f1747cac52cca6304a27eefe914329797469d5fb9519abe92386d3785f4f2c779f8f5dd95ecc8f54f8b08fd4fc94746bf273d
diff --git a/dev-util/diffoscope/diffoscope-266.ebuild
b/dev-util/diffoscope/diffoscope-266.ebuild
new file mode 100644
index 000000000000..7db31ced97d2
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-266.ebuild
@@ -0,0 +1,124 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories
different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/";
+# We could use pypi, but upstream provide distribution tarballs, so let's use
those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2";
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ || (
+ dev-python/python-magic[${PYTHON_USEDEP}]
+ sys-apps/file[python,${PYTHON_USEDEP}]
+ )
+ dev-python/libarchive-c[${PYTHON_USEDEP}]
+ dev-python/distro[${PYTHON_USEDEP}]
+ dev-python/tlsh[${PYTHON_USEDEP}]
+ acl? ( sys-apps/acl )
+ binutils? ( sys-devel/binutils )
+ bzip2? ( app-arch/bzip2 )
+ libcaca? ( media-libs/libcaca )
+ colord? ( x11-misc/colord )
+ cpio? ( app-alternatives/cpio )
+ diff? ( sys-apps/diffutils )
+ docx? ( app-text/docx2txt )
+ dtc? ( sys-apps/dtc )
+ e2fsprogs? ( sys-fs/e2fsprogs )
+ file? ( sys-apps/file )
+ find? ( sys-apps/findutils )
+ gettext? ( sys-devel/gettext )
+ gif? ( media-libs/giflib )
+ gpg? ( app-crypt/gnupg )
+ haskell? ( dev-lang/ghc )
+ hdf5? ( sci-libs/hdf5 )
+ hex? ( app-editors/vim-core )
+ imagemagick? ( media-gfx/imagemagick )
+ iso? ( app-cdr/cdrtools )
+ java? ( virtual/jdk )
+ llvm? ( sys-devel/llvm )
+ lzma? ( app-arch/xz-utils )
+ mono? ( dev-lang/mono )
+ opendocument? ( app-text/odt2txt )
+ pascal? ( dev-lang/fpc )
+ pdf? (
+ app-text/pdftk
+ app-text/poppler
+ dev-python/pypdf[${PYTHON_USEDEP}]
+ )
+ postscript? ( app-text/ghostscript-gpl )
+ R? ( dev-lang/R )
+ rpm? ( app-arch/rpm )
+ sqlite? ( dev-db/sqlite:3 )
+ squashfs? ( sys-fs/squashfs-tools )
+ ssh? ( virtual/openssh )
+ tar? ( app-arch/tar )
+ tcpdump? ( net-analyzer/tcpdump )
+ zip? ( app-arch/unzip )
+ zlib? ( app-arch/gzip )
+ zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+ test? (
+ app-arch/p7zip
+ app-text/docx2txt
+ app-text/html2text
+ media-libs/libcaca
+ virtual/imagemagick-tools[jpeg]
+ )
+"
+
+EPYTEST_DESELECT=(
+ # Test seems to use different tarball
+ tests/test_presenters.py::test_text_proper_indentation
+
+ # Needs triage
+
tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+ tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+ tests/comparators/test_gif.py::test_has_visuals
+
+ # img2txt based failures, bug #797688
+ tests/comparators/test_ico_image.py::test_diff
+ tests/comparators/test_ico_image.py::test_diff_meta
+ tests/comparators/test_ico_image.py::test_diff_meta2
+ tests/comparators/test_ico_image.py::test_has_visuals
+ tests/comparators/test_jpeg_image.py::test_diff
+ tests/comparators/test_jpeg_image.py::test_compare_non_existing
+ tests/comparators/test_jpeg_image.py::test_diff_meta
+ tests/comparators/test_jpeg_image.py::test_has_visuals
+
+ # docx2txt based falures, bug #797688
+ tests/comparators/test_docx.py::test_diff
+
+ # Formatting
+ tests/test_source.py::test_code_is_black_clean
+
+ # Fails on ZFS
+ tests/test_main.py::test_non_unicode_filename
+
+ # Fails on (unreleased) LLVM 16 with minor difference
+ #tests/comparators/test_macho.py::test_llvm_diff
+ #tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest
