commit: a5eb5078e019023d99ae4f737ca23ab6bce2ff4c
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri May 24 18:55:59 2024 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri May 24 19:26:15 2024 +0000
URL: https://gitweb.gentoo.org/proj/kde.git/commit/?id=a5eb5078
kde-plasma/print-manager: 6.0.90 version bump
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
.../print-manager/print-manager-6.0.90.ebuild | 69 ++++++++++++++++++++++
1 file changed, 69 insertions(+)
diff --git a/kde-plasma/print-manager/print-manager-6.0.90.ebuild
b/kde-plasma/print-manager/print-manager-6.0.90.ebuild
new file mode 100644
index 0000000000..72cd4e28be
--- /dev/null
+++ b/kde-plasma/print-manager/print-manager-6.0.90.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=6.2.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.7.1
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Manage CUPS print jobs and printers in Plasma"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="+gtk"
+
+DEPEND="
+ >=dev-qt/qt5compat-${QTMIN}:6
+ >=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+ >=dev-qt/qtdeclarative-${QTMIN}:6
+ >=kde-frameworks/kcmutils-${KFMIN}:6
+ >=kde-frameworks/kconfig-${KFMIN}:6
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:6
+ >=kde-frameworks/kcoreaddons-${KFMIN}:6
+ >=kde-frameworks/kdbusaddons-${KFMIN}:6
+ >=kde-frameworks/ki18n-${KFMIN}:6
+ >=kde-frameworks/kiconthemes-${KFMIN}:6
+ >=kde-frameworks/kio-${KFMIN}:6
+ >=kde-frameworks/kirigami-${KFMIN}:6
+ >=kde-frameworks/knotifications-${KFMIN}:6
+ >=kde-frameworks/kservice-${KFMIN}:6
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+ >=kde-frameworks/kwindowsystem-${KFMIN}:6
+ >=kde-plasma/libplasma-${PVCUT}:6
+ net-print/cups
+"
+RDEPEND="${DEPEND}
+ !<kde-plasma/print-manager-23.08.5-r100:5
+ >=kde-frameworks/kdeclarative-${KFMIN}:6
+ kde-plasma/kde-cli-tools:*
+ gtk? ( app-admin/system-config-printer )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
+
+src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON # not packaged
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ ecm_pkg_postinst
+
+ if [[ -z "${REPLACING_VERSIONS}" ]] && ! use gtk ; then
+ ewarn "By switching off \"gtk\" USE flag, you have chosen to do
without"
+ ewarn "an important, though optional, runtime dependency:"
+ ewarn
+ ewarn "app-admin/system-config-printer"
+ ewarn
+ ewarn "${PN} will work nevertheless, but is going to be less
comfortable"
+ ewarn "and will show the following error status during runtime:"
+ ewarn
+ ewarn "\"Failed to group devices: 'The name
org.fedoraproject.Config.Printing"
+ ewarn "was not provided by any .service files'\""
+ fi
+}
